[STOCK] create_beamspot

[Milashkasiya]

Descripción:
Esta vez me puse a debugear un efecto que me gustó mucho del Half-Life Singleplayer y preparé un Stock un poco limitado pero funcional.



Video:
Imagen del efecto hecho con el plugin de ejemplo:


Video (El stock no incluye los efectos de ScreenFade ni ScreenShake)
http://youtu.be/BQKD6V1aBPU

Modulos requeridos:
- Engine

Sintaxis:
stock create_beamspot( Float:origin[3], color[3], const classname[] )

1. origin: Es punto centro del efecto.
   
2. color: Color RGB del efecto.
   
3. classname: Classname asignado al info_target centro que pueden utilizar en otras funciones o plugins

Stock:

Código PHP:

stock create_beamspot( Float:origin[3], color[3], const classname[] )
{
    #define MAX_CORNERS 8
    static const Float:corners[ MAX_CORNERS ][ 3 ] =
    {
        // 3 top corners
        {  36.0, 0.0,  51.0 },
        {   0.0, 0.0,  51.0 },
        { -36.0, 0.0,  51.0 },
        // 3 bottom corners
        { -36.0, 0.0, -51.0 },
        {   0.0, 0.0, -51.0 },
        {  36.0, 0.0, -51.0 },
        // left - right
        {  51.0, 0.0,   0.0 },
        { -51.0, 0.0,   0.0 }
    };
    
    static j;
    
    new tname[ 4 ] = "t";
    formatex( tname[1], charsmax(tname) - 1, "%i", ++j );
    
    new cname[ 10 ];
    new pos = formatex( cname, charsmax(cname), "%s_spin1", tname ) - 1;
    
    new main = create_entity( "info_target" );
    DispatchKeyValue( main, "targetname", tname );
    entity_set_string( main, EV_SZ_classname, classname );
    entity_set_size( main, Float:{-16.0,-16.0,-16.0}, Float:{16.0,16.0,16.0} );
    entity_set_int( main, EV_INT_solid, SOLID_TRIGGER );
    entity_set_origin( main, origin );
    
    new Float:vcolor[ 3 ];
    vcolor[ 0 ] = float( color[0] );
    vcolor[ 1 ] = float( color[1] );
    vcolor[ 2 ] = float( color[2] );
    
    new entity;
    new Float:corner[ 3 ];
    
    for( new i; i < MAX_CORNERS; i++ )
    {
        corner[ 0 ] = origin[ 0 ] + corners[ i ][ 0 ];
        corner[ 1 ] = origin[ 1 ] + corners[ i ][ 1 ];
        corner[ 2 ] = origin[ 2 ] + corners[ i ][ 2 ];
        
        entity = create_entity( "info_target" );
        DispatchKeyValue( entity, "targetname", cname );
        entity_set_origin( entity, corner );
        
        entity = create_entity( "env_beam" );
        DispatchKeyValue( entity, "Radius", "255" );
        DispatchKeyValue( entity, "StrikeTime", "1" );
        DispatchKeyValue( entity, "TextureScroll", "10" );
        DispatchKeyValue( entity, "texture", spr_lgtning );
        DispatchKeyValue( entity, "NoiseAmplitude", "2" );
        DispatchKeyValue( entity, "BoltWidth", "200" );
        DispatchKeyValue( entity, "renderamt", "255" );
        DispatchKeyValue( entity, "LightningEnd", cname );
        DispatchKeyValue( entity, "LightningStart", tname );
        entity_set_vector( entity, EV_VEC_rendercolor, vcolor );
        entity_set_int( entity, EV_INT_spawnflags, SF_BEAM_STARTON | SF_BEAM_SHADEOUT );
        DispatchSpawn( entity );    

        cname[ pos ] = 50 + i;
    }
    
    return main;
} 


En este stock, el valor de spr_lgtning es:

Código PHP:

new const spr_lgtning[ ] = "sprites/lgtning.spr" 


NOTAS:

• Si deseas cambiar el ángulo del efecto en conjunto, será necesario jugar con los valores de corners. Pensaba hacerlo más dinámico, pero lamentablemente no sé cómo :/.

[Metrikcz]

Disculpa mi ignorancia es cs ? en el video parece HL

[Milashkasiya]

Disculpa mi ignorancia es cs ? en el video parece HL

Para cualquier mod que soporte env_beam e info_target

[cLAANS]

Esta muy bueno, seguramente le dare una utilidad.

Gracias

Saludos,
cLAANS.-

[Mía]

Bonísimo! Gracias por aportarlo.

[LNATIC]

Muy bueno, además de que esta hecho con engine :3

Saludos

[roccoxx]

me encanto jeje, porque decis que es algo limitado tu stock?

[Milashkasiya]

me encanto jeje, porque decis que es algo limitado tu stock?

Como ves en la imagen:

La entidad esta en direccion hacia a mi, se podria decir que esta "mirandome", pero si quiero que mire a la pared de la izquierda o derecha, tendria que modificar los corners del stock :/

[[R]ak]

deberias retornar el id de la entidad y dejarle el classname con el name que le pasas;

btw.. buen aporte

[roccoxx]

deberias retornar el id de la entidad y dejarle el classname con el name que le pasas;

btw.. buen aporte

si porque para removerlos se complica jajaja, son muchas entidades.

[Milashkasiya]

Stock y Plugin de ejemplo actualizado.

Ahora el stock devuelve la entidad principal (centro del efecto).
El color es RGB simple (ya no en Float)
Si quieren remover todas las entidades, no podran asi que tendran que armar su propia funcion

[roccoxx]

Stock y Plugin de ejemplo actualizado.

Ahora el stock devuelve la entidad principal (centro del efecto).
El color es RGB simple (ya no en Float)
Si quieren remover todas las entidades, no podran asi que tendran que armar su propia funcion

y yo que queria ahorrarme el trabajo

[kev1]

Muy bueno!

[Metrikcz]

Quiero hacer un efecto de aparición en el portal, los creo y los hago invisibles, lo que quiero es que paresca que algo sale del portal entonces lo hago visible y quiero que se vaya haciendo mas grande, osea lo hago visible, lo hago chiquito, lo hago mediano, lo hago ya normal y respawneo ya la entidad o player y vuelvo a hacer invisible el portal, pero como hago lo de chiquito a mas grande ?

[Milashkasiya]

Quiero hacer un efecto de aparición en el portal, los creo y los hago invisibles, lo que quiero es que paresca que algo sale del portal entonces lo hago visible y quiero que se vaya haciendo mas grande, osea lo hago visible, lo hago chiquito, lo hago mediano, lo hago ya normal y respawneo ya la entidad o player y vuelvo a hacer invisible el portal, pero como hago lo de chiquito a mas grande ?

Prueba con pev_scale

[OrangePeel]

i think this better, it can be created in anytime.
https://forums.alliedmods.net/showthread...light=beam

Código:

stock create_beamspot2( Float:origin[3] )
{
#define MAX_CORNERS 8
static const Float:corners[ MAX_CORNERS ][ 3 ] =
{
// 3 top corners
{  36.0, 0.0,  51.0 },
{  0.0, 0.0,  51.0 },
{ -36.0, 0.0,  51.0 },
// 3 bottom corners
{ -36.0, 0.0, -51.0 },
{  0.0, 0.0, -51.0 },
{  36.0, 0.0, -51.0 },
// left - right
{  51.0, 0.0,  0.0 },
{ -51.0, 0.0,  0.0 }
};

new Float:corner[ 3 ];

for( new i; i < MAX_CORNERS; i++ )
{
new beam = Beam_Create(spr_lgtning, 200.0)
if(beam == FM_NULLENT)
continue

corner[ 0 ] = origin[ 0 ] + corners[ i ][ 0 ];
corner[ 1 ] = origin[ 1 ] + corners[ i ][ 1 ];
corner[ 2 ] = origin[ 2 ] + corners[ i ][ 2 ];

Beam_SetColor(beam, {155.0, 0.0, 155.0})
Beam_SetNoise(beam, 2)
Beam_SetBrightness(beam, 255.0)
Beam_SetScrollRate(beam, 10.0)
Beam_SetFlags(beam, BEAM_FSHADEOUT)
Beam_PointsInit(beam, origin, corner)
}
}