Ayuda configurar mapas [TTT]

[alanfx]

Buenas, no se en donde vaya esto pero necesito ayuda con mi servidor para configurar algunos mapas [TTT] para que los traidores puedan abrir las puertas y no todos, etc. Alguien que me diga como?

[Manu]

¿Tenés algún ejemplo?

[alanfx]

En algunos mapas, hay unas puertas que solo los traidores pueden abrir, en este caso todos pueden abrirlas. y no se como configurar eso

[Manu]

Se hace por un plugin, pero tendrías que pasar los mapas para saber que entidades son.

[alanfx]

Pues hay varios, entre, ttt_towers_fix, ttt_little_house, y creo que otros más.

[Manu]

Quería comprobar que estuvieras hablando de los mapas que creé hace un tiempo Acá te dejo dos plugins, uno que maneja el ttt_towers_fix y otro que maneja el ttt_little_house.

Cada uno tiene que ser activado solo cuando se carga cada mapa respectivamente. La manera fácil de hacerlo es crear un "plugins.ini" para cada mapa en particular. Por ejemplo, se puede crear un plugins-ttt_little_house.ini y escribir dentro el nombre del .amxx que administra el Little House, y luego mover dicho .ini a una carpeta dentro de configs que ya no recuerdo como debe llamarse.

ttt_towers_fix

Código PHP:

#include <amxmodx>
#include <engine>
#include <fakemeta>
#include <hamsandwich>
#include <ttt>
#include <xs>

/* ========================================================================
*                 [ Globals & Macros ]
* ======================================================================== */

#define ID_RESULT ( iTaskId - TASK_RESULT )

#define IsPlayerValid(%0) ( 1 <= %0 <= 32 )
#define IsEntityModded(%0) ( %0[ 0 ] == 't' && %0[ 4 ] == 't' )
#define IsPlayerFrozen(%0) ( entity_get_int( %0, EV_INT_flags ) & FL_FROZEN )
#define IsButtonUsable(%0) ( entity_get_float( %0, EV_FL_fuser1 ) <= get_gametime( ) )
#define IsEntityAlive(%0) ( entity_get_float( %0, EV_FL_health ) > 0.0 )

const TASK_RESULT = 747;

enum _:Entity_Type
{
    Entity_Work,
    Entity_Room,
    Entity_Wood,
    Entity_Place,
    Entity_Tester,
    Entity_Explosive
}

new g_iEntities[ Entity_Type ];

/* ========================================================================
*                 [ Initiation ]
* ========================================================================= */

public plugin_init( )
{
    register_plugin( "[TTT] Towers Manager", "1.0", "Manu" );
    
    RegisterHam( Ham_Use, "func_button", "fw_PlayerButton_Pre", false );
    
    g_iEntities[ Entity_Work ] = find_ent_by_tname( -1, "traitwork" );
    g_iEntities[ Entity_Room ] = find_ent_by_tname( -1, "traitroom" );
    g_iEntities[ Entity_Wood ] = find_ent_by_tname( -1, "traitwood" );
    g_iEntities[ Entity_Place ] = find_ent_by_tname( -1, "traitplace" );
    g_iEntities[ Entity_Tester ] = find_ent_by_tname( -1, "traittester" );
    g_iEntities[ Entity_Explosive ] = find_ent_by_tname( -1, "traitexplosive" );
}

public ttt_gamemode( iGamemode )
{
    if( iGamemode == GAME_PREPARING )
    {
        entity_set_float( g_iEntities[ Entity_Room ], EV_FL_fuser1, 0.0 );
        entity_set_float( g_iEntities[ Entity_Wood ], EV_FL_fuser1, 0.0 );
        entity_set_float( g_iEntities[ Entity_Tester ], EV_FL_fuser1, 0.0 );
        entity_set_float( g_iEntities[ Entity_Explosive ], EV_FL_fuser1, 0.0 );
    }
}

/* ========================================================================
*                 [ Hamsandwich ]
 * ======================================================================== */

public fw_PlayerButton_Pre( iEnt, iId, iActivator, iUseType, Float:fValue )
{
    static szTarget[ 16 ]; entity_get_string( iEnt, EV_SZ_targetname, szTarget, charsmax( szTarget ) );
    
    if( iUseType == 2 && fValue == 1.0 && IsEntityModded( szTarget ) && IsButtonUsable( iEnt ) && is_user_alive( iId ) )
    {
        if( szTarget[ 5 ] == 't' )
        {
            if( IsEntityAlive( g_iEntities[ Entity_Work ] ) )
            {
                new iOrigin[ 3 ];
                new iPlayer = GetTesteablePlayer( );
                
                if( IsPlayerValid( iPlayer ) )
                {
                    get_user_origin( iPlayer, iOrigin );
                    
                    message_begin( MSG_BROADCAST, SVC_TEMPENTITY );
                    write_byte( TE_IMPLOSION );
                    write_coord( iOrigin[ 0 ] );
                    write_coord( iOrigin[ 1 ] );
                    write_coord( iOrigin[ 2 ] );
                    write_byte( 200 );
                    write_byte( 25 );
                    write_byte( 28 );
                    message_end( );
                    
                    set_task( 3.0, "ShowResults", iPlayer + TASK_RESULT );
                    
                    entity_set_float( iEnt, EV_FL_fuser1, get_gametime( ) + 20.0 );
                    entity_set_int( iPlayer, EV_INT_flags, entity_get_int( iPlayer, EV_INT_flags ) | FL_FROZEN );
                    
                    client_print_color( 0, print_team_default, "^x04[TTT]^x01 No podras moverte hasta que termine la prueba." );
                }
                else
                {
                    client_print_color( 0, print_team_default, "^x04[TTT]^x01 No hay ningun jugador sobre la plataforma." );
                    
                    entity_set_float( iEnt, EV_FL_fuser1, get_gametime( ) + 3.0 );
                }
            }
            else
            {
                client_print_color( 0, print_team_default, "^x04[TTT]^x01 El tester fue destruido." );
            }
        }
        else
        {
            if( ttt_get_playerstate( iId ) == PC_TRAITOR )
            {
                switch( szTarget[ 5 ] )
                {
                    case 'r':
                    {
                        client_print_color( 0, print_team_default, "^x04[TTT]^x01 No puedes ^"campear^" adentro de este lugar." );
                        
                        entity_set_float( iEnt, EV_FL_fuser1, get_gametime( ) + 10.0 );
                        
                        return HAM_IGNORED;
                    }
                    case 'w':
                    {
                        client_print_color( 0, print_team_default, "^x04[TTT]^x01 Los puentes han sido destruidos." );
                        
                        entity_set_float( iEnt, EV_FL_fuser1, get_gametime( ) + 500.0 );
                    }
                    case 'e':
                    {
                        client_print_color( 0, print_team_default, "^x04[TTT]^x01 La caja de explosivos ha sido detonada." );
                        
                        entity_set_float( iEnt, EV_FL_fuser1, get_gametime( ) + 500.0 );
                    }
                }
            }
            else
            {
                client_print_color( 0, print_team_default, "^x04[TTT]^x01 Solo los traidores tienen acceso a este boton." );
            }
        }
        
        return HAM_SUPERCEDE;
    }
    
    return HAM_IGNORED;
}

/* ========================================================================
*                 [ Public Functions ]
 * ======================================================================== */
 
public ShowResults( iTaskId )
{
    new iState = ttt_get_playerstate( ID_RESULT );
    
    set_rendering( ID_RESULT, kRenderFxGlowShell, g_iTeamColors[ iState ][ 0 ], g_iTeamColors[ iState ][ 1 ], g_iTeamColors[ iState ][ 2 ], kRenderNormal, 50 );
    entity_set_int( ID_RESULT, EV_INT_flags, entity_get_int( ID_RESULT, EV_INT_flags ) & ~FL_FROZEN );
    
    set_task( 3.0, "RemoveGlowing", ID_RESULT );
}

public RemoveGlowing( iId )
{
    if( is_user_alive( iId ) )
    {
        set_rendering( iId );
    }
}

/* ========================================================================
*                 [ Private Functions ]
 * ======================================================================== */

GetTesteablePlayer( )
{
    new iNum, iPlayers[ 32 ];
    
    get_players( iPlayers, iNum, "a" );
    
    for( iNum--; iNum >= 0; iNum-- )
    {
        if( entity_range( iPlayers[ iNum ], g_iEntities[ Entity_Place ] ) > 32.0 )
        {
            continue;
        }
        
        return iPlayers[ iNum ];
    }
    
    return 0;
} 


ttt_little_house

Código PHP:

#include <amxmodx>
#include <engine>
#include <fakemeta>
#include <hamsandwich>
#include <ttt>
#include <xs>

/* ========================================================================
*                 [ Globals & Macros ]
* ======================================================================== */

#define MIN_DIST 16.0

#define IsModdedEntity(%0) ( %0[ 0 ] == 't' && %0[ 4 ] == 't' )
#define IsButtonUsable(%0) ( entity_get_float( %0, EV_FL_fuser1 ) <= get_gametime( ) )

const TASK_FOG = 1111;

enum
{
    END_POINT = -1,
    ZOMBIE_POINT = EV_INT_iuser2,
    ZOMBIE_RUN = 4,
    ZOMBIE_IDLE = 1,
    ZOMBIE_ATTACK = 75
}

enum _:Entity_Type
{
    Entity_Fog,
    Entity_Start,
    Entity_Zombie
}

new g_iOwner, g_iMaxPlayers, g_iEntities[ Entity_Type ];

new const g_szZombieModel[ ] = "models/ttt_little_house/zombie.mdl";
new const g_szZombieClassname[ ] = "ttt_zombie";

/* ========================================================================
*                 [ Initiation ]
* ======================================================================== */

public plugin_precache( )
{
    precache_model( g_szZombieModel );
}

public plugin_init( )
{
    register_plugin( "[TTT] Little House Manager", "1.0", "Manu" );
    
    RegisterHam( Ham_Use, "func_button", "fw_PlayerButton_Pre", false );
    register_think( g_szZombieClassname,"think_Zombie" );
    
    set_cvar_num( "sv_skycolor_r", 0 );
    set_cvar_num( "sv_skycolor_g", 0 );
    set_cvar_num( "sv_skycolor_b", 0 );
    
    g_iMaxPlayers = get_maxplayers( );
    
    g_iEntities[ Entity_Fog ] = find_ent_by_tname( -1, "traitfog" );
    g_iEntities[ Entity_Start ] = find_ent_by_tname( -1, "zmplace" );
    g_iEntities[ Entity_Zombie ] = find_ent_by_tname( -1, "traitzm" );
}

public ttt_gamemode( iGamemode )
{
    if( iGamemode == GAME_ENDED || iGamemode == GAME_PREPARING )
    {
        if( task_exists( TASK_FOG ) )
        {
            RemoveFog( );
            remove_task( TASK_FOG );
        }
        
        RemoveZombie( );
        
        entity_set_float( g_iEntities[ Entity_Fog ], EV_FL_fuser1, 0.0 );
        entity_set_float( g_iEntities[ Entity_Zombie ], EV_FL_fuser1, 0.0 );
    }
}

/* ========================================================================
*                 [ Zombie's brain ]
 * ======================================================================== */

public think_Zombie( iEnt )
{
    new iPoint = entity_get_int( iEnt, ZOMBIE_POINT );
    
    if( entity_range( iEnt, iPoint ) < MIN_DIST )
    {
        static szData[32];
        
        entity_get_string( iPoint, EV_SZ_target, szData, charsmax( szData ) );
        entity_set_int( iEnt, ZOMBIE_POINT, ( iPoint = find_ent_by_tname( -1, szData ) ) );
        
        if( !is_valid_ent( iPoint ) )
        {
            remove_entity( iEnt );
            
            g_iOwner = -1;
            
            return;
        }
    }
    
    entity_set_float( iEnt, EV_FL_nextthink, get_gametime( ) + 0.1 );
    
    WalkToEntity( iEnt, iPoint );
    KillNearPlayers( iEnt );
}

/* ========================================================================
*                 [ Hamsandwich ]
 * ======================================================================== */

public fw_PlayerButton_Pre( iEnt, iId, iActivator, iUseType, Float:fValue )
{
    static szTarget[ 16 ]; entity_get_string( iEnt, EV_SZ_targetname, szTarget, charsmax( szTarget ) );
    
    if( iUseType == 2 && fValue == 1.0 && IsModdedEntity( szTarget ) && IsButtonUsable( iEnt ) && is_user_alive( iId ) )
    {
        if( ttt_get_playerstate( iId ) == PC_TRAITOR )
        {
            switch( szTarget[ 5 ] )
            {
                case 'f':
                {
                    message_begin( MSG_BROADCAST, get_user_msgid( "Fog" ), { 0, 0, 0 }, 0 );
                    write_byte( 175 );
                    write_byte( 175 );
                    write_byte( 175 );
                    write_byte( 90 );
                    write_byte( 101 );
                    write_byte( 68 );
                    write_byte( 59 );
                    message_end( );
                    
                    entity_set_float( iEnt, EV_FL_fuser1, get_gametime( ) + 90.0 );
                    
                    set_task( 30.0, "RemoveFog", TASK_FOG );
                    
                    client_print_color( 0, print_team_default, "^x04[TTT]^x01 Una niebla ha cubierto el mapa durante 30 segundos." );
                }
                case 'z':
                {
                    CreateZombie( iId );
                    
                    entity_set_float( iEnt, EV_FL_fuser1, get_gametime( ) + 90.0 );
                    
                    client_print_color( 0, print_team_default, "^x04[TTT]^x01 Un zombie fue liberado en las alcantarillas." );
                }
            }
        }
        else
        {
            client_print_color( 0, print_team_default, "^x04[TTT]^x01 Solo los traidores tienen acceso a este boton." );
            
            return HAM_SUPERCEDE;
        }
    }
    
    return HAM_IGNORED;
}

/* ========================================================================
*                 [ Public Functions ]
 * ======================================================================== */

public client_disconnected( iId )
{
    if( g_iOwner == iId )
    {
        RemoveZombie( );
    }
}

public RemoveFog( )
{
    message_begin( MSG_BROADCAST, get_user_msgid( "Fog" ), { 0, 0, 0 }, 0 );
    write_byte( 0 );
    write_byte( 0 );
    write_byte( 0 );
    write_byte( 0 );
    write_byte( 0 );
    write_byte( 0 );
    write_byte( 0 );
    message_end( );
}

/* ========================================================================
*                 [ Private Functions ]
 * ======================================================================== */

RemoveZombie( )
{
    new iEnt = find_ent_by_class( -1, g_szZombieClassname );
    
    if( is_valid_ent( iEnt ) )
    {
        remove_entity( iEnt );
    }
}

CreateZombie( const iOwner )
{
    new iEnt, Float:fOrigin[ 3 ];
    
    if( !is_valid_ent( ( iEnt = create_entity( "info_target" ) ) ) )
    {
        return;
    }
    
    g_iOwner = iOwner;
    
    entity_set_string( iEnt, EV_SZ_classname, g_szZombieClassname );
    
    entity_set_model( iEnt, g_szZombieModel );
    entity_set_size( iEnt, Float:{ -16.0,-16.0,-32.0 }, Float:{ 16.0,16.0,32.0 } );
    
    entity_set_int( iEnt, EV_INT_movetype, MOVETYPE_PUSHSTEP );
    entity_set_int( iEnt, EV_INT_solid, SOLID_TRIGGER );
    entity_set_int( iEnt, ZOMBIE_POINT, find_ent_by_tname( 0, "zm_point1" ) );
    
    entity_get_vector( g_iEntities[ Entity_Start ], EV_VEC_origin, fOrigin );
    entity_set_origin( iEnt, fOrigin );
    
    entity_set_float( iEnt, EV_FL_health, 500.0 );
    entity_set_float( iEnt, EV_FL_takedamage, DAMAGE_YES );
    entity_set_float( iEnt, EV_FL_gravity, 1.0 );
    
    entity_set_float( iEnt, EV_FL_nextthink, get_gametime( ) + 0.1 );
    
    drop_to_floor( iEnt );
    
    PlaySequence( iEnt, ZOMBIE_IDLE );
}

WalkToEntity( iEnt, iTarget )
{
    static Float:fOrigin[ 3 ], Float:fTarget[ 3 ], Float:fAngles[ 3 ];
    
    entity_get_vector( iEnt, EV_VEC_origin, fOrigin );
    entity_get_vector( iTarget, EV_VEC_origin, fTarget );
    
    xs_vec_sub( fTarget, fOrigin, fTarget );
    xs_vec_normalize( fTarget, fTarget );
    vector_to_angle( fTarget, fAngles );
    xs_vec_mul_scalar( fTarget, 16.0, fTarget );
    
    fAngles[ 0 ] = 0.0;
    
    entity_set_vector( iEnt, EV_VEC_angles, fAngles );
    entity_set_vector( iEnt, EV_VEC_velocity, fTarget );
    
    engfunc( EngFunc_WalkMove, iEnt, fAngles[ 1 ], 20.0, WALKMOVE_NORMAL );
    
    if( entity_get_int( iEnt, EV_INT_sequence ) != ZOMBIE_RUN )
    {
        PlaySequence( iEnt, ZOMBIE_RUN );
    }
}

KillNearPlayers( iEnt )
{
    for( new iId; iId <= g_iMaxPlayers; iId++ )
    {
        if( is_user_alive( iId ) && entity_range( iEnt, iId ) < 64.0 )
        {
            PlaySequence( iEnt, ZOMBIE_ATTACK );
            ExecuteHam( Ham_Killed, iId, g_iOwner, 0 );
            entity_set_float( iEnt, EV_FL_nextthink, get_gametime( ) + 1.0 );
            
            break;
        }
    }
}

PlaySequence( iEnt, iSequence )
{
    if( !is_valid_ent( iEnt ) )
    {
        return;
    }
    
    entity_set_float( iEnt, EV_FL_animtime, get_gametime( ) );
    entity_set_float( iEnt, EV_FL_framerate, 1.0 );
    entity_set_int( iEnt, EV_INT_sequence, iSequence );
} 


[alanfx]

Se debe crear una carpeta "maps" y dentro meter ese .ini y dentro de el .ini poner el nombre de el plugin??

// osea que se tiene que crear un plugin para cada mapa? y así con sus entidades? es que yo mire otros mapas que tenian asi puertas de traidores y así, creo que mire el ttt_construct o algo así

[Manu]

No necesariamente es un plugin para cada mapa, pasa que yo solo hice dos y como son tan diferentes uno del otro entonces los hice por separado.

Si tenés distintas ideas para cada mapa entonces es preferible hacer un plugin para cada a menos que pienses tener varios mapas con entidades que solo sean usables por traidores, pero no vas a encontrar muchos mapas así (posiblemente ninguno, porque implica crear un mapa).

Si estás dispuesto a crear los mapas entonces posiblemente te convenga un plugin general con distintas funcionalidades para poder manejar de forma genérica esos mapas "custom".

EDIT: Si, creo que va en maps.

[alanfx]

Gracias