Block DAMAGE y hacer algo al mismo tiempo

[acesino25]

Hola en esto que estuve renegando necesitaba lograr bloquear el damage entre players del mismo team y sacarle vida al que esta lastimando a su mismo team... si alguien pudiese ayudarme les estaria muy agradecido.

Código PHP:

#include <amxmodx>
#include <fun>

new CvarDmg;

public plugin_init() 
{
    register_plugin("[ZP] ZClass: Mirror Zombie", "1.8", "007")
    CvarDmg = register_cvar("Cvar_Dmg","5.0")
    register_event("Damage", "mirror_dmg", "b", "2!0", "3=0", "4!0")
} 

public mirror_dmg(id)
{
    new damage = read_data(2) // Get damage
    new victim = read_data(0) // Victim(Thats you!)
    new attacker = get_user_attacker(victim) // Attacker(Your enemy)
    new teamattacker, teamvictim;
    teamattacker = get_user_team(attacker);
    teamvictim = get_user_team(victim);
    
    //Son del mismo team?
    if(teamattacker != teamvictim)
        return PLUGIN_HANDLED;
        
    // Not alive
    if(!is_user_alive(id))
        return PLUGIN_HANDLED
    
    if(victim != attacker) // The victim cannot be himself
    {
        
        new HP = get_user_health(attacker) - get_pcvar_float(CvarDmg)
        new HPv = get_user_health(victim) + get_pcvar_float(CvarDmg)
        
        if(HP > 0)
        {
            set_user_health(attacker,(HP));
            if(get_user_health(victim) < 100)
            {
                set_user_health(victim, (HPv));
            }
        }
        else 
        {
            user_kill(attacker)
            if(get_user_health(victim) < 100)
            {
                set_user_health(victim, (HPv));
            }
        }
    }
    return PLUGIN_HANDLED
} 


[Matians]

Código PHP:

#include <amxmodx>
#include <amxmisc>
#include <hamsandwich>

public plugin_init()
{
    register_plugin( "No team damage", "1.0", ":whatever:" );
    
    RegisterHam( Ham_TakeDamage, "player", "Ham_PlayerTakeDamage" );
}

public Ham_PlayerTakeDamage(victim, inflictor, attacker, Float:damage, iDamageBits)
{
    if( !is_user_connected(victim) || !is_user_connected(attacker) )
    {
        return HAM_IGNORED;
    }
    
    if( get_user_team(victim) == get_user_team(attacker) )
    {
        set_user_health(attacker, get_user_health(attacker)-damage);
        client_print(attacker, print_center, "Recibiste danio por atacar a tu team");
        
        return HAM_IGNORED;
    }
    
    return HAM_IGNORED;    
} 


[Manu]

Código PHP:

#include <amxmodx>
#include <hamsandwich>

/* =================================================
*         [ Initiation & Global stuff ]
* ================================================== */

#define GetPlayerBit(%1,%2) ( %1 & ( 1 << ( %2 & 31 ) ) )
#define SetPlayerBit(%1,%2) ( %1 |= ( 1 << ( %2 & 31 ) ) )
#define ClearPlayerBit(%1,%2) ( %1 &= ~( 1 << ( %2 & 31 ) ) )

#define isPlayerValid(%0) ( 1 <= %0 <= 32 )
#define isPlayerTeammate(%0,%1) ( get_user_team(%0) == get_user_team(%1) )

new g_iConnected, g_pCvarFriendlyFire, HamHook:g_pTakeDamage;

public plugin_init( )
{
    register_plugin( "Self-damage", "1.0", "Manu" );
    
    register_logevent( "ev_RoundStart", 2, "1=Round_Start" );
    
    g_pTakeDamage = RegisterHam( Ham_TakeDamage, "player", "fw_PlayerTakeDamage_Pre", false );
    
    g_pCvarFriendlyFire    = get_cvar_pointer( "mp_friendlyfire" );
}

public plugin_cfg( )
{
    if( is_plugin_loaded( "Pause Plugins" ) != -1 )
        server_cmd( "amx_pausecfg add ^"Self-damage^"" );
}

public fw_PlayerTakeDamage_Pre( iVictim, iInflictor, iAttacker, Float:fDamage, iDamageBits )
{
    if( isPlayerValid( iAttacker ) && ( iVictim != iAttacker ) && GetPlayerBit( g_iConnected, iAttacker ) && isPlayerTeammate( iAttacker, iVictim ) )
    {
        ExecuteHamB( Ham_TakeDamage, iAttacker, iInflictor, iAttacker, fDamage / 3.0, DMG_GENERIC );
        
        return HAM_SUPERCEDE;
    }
    
    return HAM_IGNORED;
}

public ev_RoundStart( )
{
    ( get_pcvar_num( g_pCvarFriendlyFire ) > 0 ) ? EnableHamForward( g_pTakeDamage ) : DisableHamForward( g_pTakeDamage );
}    

public client_putinserver( iId ) SetPlayerBit( g_iConnected, iId );
public client_disconnect( iId ) ClearPlayerBit( g_iConnected, iId ); 


[hud]

Código PHP:

#include <amxmodx>
#include <hamsandwich>

#define PLUGIN "Simple Mirror Damage"
#define VERSION "1.0"
#define AUTOR "Pancho.-'+hud;Erater"

#define is_user_valid_connected(%1) (1 <= %1 <= MaxPlayers && is_user_connected(%1))

new MaxPlayers;

public plugin_init()
{
    register_plugin( PLUGIN, VERSION, AUTOR );
    
    RegisterHam(Ham_TakeDamage, "player", "Ham_PlayerTakeDamage");
    
    MaxPlayers = get_maxplayers();
}

public Ham_PlayerTakeDamage(victim, inflictor, attacker, Float:damage, damage_type)
{
    if( victim != attacker && is_user_valid_connected(attacker) )
    {
        if( get_user_team(attacker) == get_user_team(victim) )
        {
            SetHamParamEntity(1, attacker);
            SetHamParamEntity(3, victim);
        }
    }
    
    return HAM_IGNORED;
} 


[Matians]

Una pregunta, que los parametros de takedamage, no son, Victim, Inflictor y Attacker? No me acuerdo, pero pienso y me sale victim inflictor y attacker o como es pre son diferentes? Ya ni me acuerdo

[hud]

Una pregunta, que los parametros de takedamage, no son, Victim, Inflictor y Attacker? No me acuerdo, pero pienso y me sale victim inflictor y attacker o como es pre son diferentes? Ya ni me acuerdo

[ +Info ]