Comando para que el admin remueva su skin

[rojedafeik]

Hola!, estoy buscando algún plugin donde el admin pueda remover su skin por medio de comando. Ejemplo /remove o que aparezca un menú donde diga quieres remover tu skin temporalmente? si, no.


Gracias y espero que me puedan ayudar.

[PredatorFlys]

especifica que skin?
armas, cuerpo?
hacerte invisible, armas invisibles?
o usas plugin plugin para cambiar models y quieres removerlos temporalmente?

[OsweRRR]

cs_reset_user_model de cstrike

[PredatorFlys]

cs_reset_user_model de cstrike

rg_reset_user_model(index)

[La Renga Mk]

cs_reset_player_model(id)

https://forums.alliedmods.net/showthread.php?t=161255

[rojedafeik]

especifica que skin?
armas, cuerpo?
hacerte invisible, armas invisibles?
o usas plugin plugin para cambiar models y quieres removerlos temporalmente?

Hola, solo el cuerpo, tengo un plugin donde desactiva su perfix osea el tag que tiene [Dueño, admin etc] y no es que se haga invisible, solo que el admin tenga el skin normal de player y se haga pasar como si no fuera admin

[La Renga Mk]

esto no se van a dar cuenta que es admin pero va a ser el unico que se puede poner el model fijate si te sirve lo busque en GOOGLE

Código PHP:

#include <amxmodx>    
#include <amxmisc>    
#include <cstrike>    
  
#define PLUGIN "Menu models"    
#define VERSION "2.0"    
#define AUTHOR "Lol"    

new const Models[][] = {
    "admin_tt_1",
    "admin_tt_2",
    "admin_tt_3"
} 

public plugin_precache() { 
     
    new buffer[64] 
    for(new i; i < sizeof Models; i++) { 
         
        formatex(buffer, charsmax(buffer), "models/player/%s/%s.mdl", Models[i], Models[i]) 
        precache_model(buffer) 
} 
            
} 

public plugin_init() {    
     
    register_plugin(PLUGIN, VERSION, AUTHOR)    
    register_clcmd("say /model", "Modelsr")       

}  
public Modelsr(id)    
{    
    if(get_user_flags(id) & ADMIN_IMMUNITY)  
    {          
        new menu = menu_create("Menu de Modelos VIP", "Modelsr_mostrar")    
         
        for(new i; i < sizeof Models; i++) 
            menu_additem(menu, Models[i])  

        menu_additem(menu, "normal") 
        menu_setprop(menu, MPROP_EXITNAME, "Salir");    
        menu_setprop(menu, MPROP_NEXTNAME, "Mas")   
        menu_setprop(menu, MPROP_BACKNAME, "Atras")   
        menu_setprop(menu, MPROP_EXIT, MEXIT_ALL);   
         
        menu_display(id, menu);  
    } 
    else 
        client_print(id, print_chat, "No puedes ponerte los modelos porque no eres VIP!!") 
     
    
    return PLUGIN_HANDLED 
}    

public Modelsr_mostrar(id, menu, item)    
{    
    if(item == MENU_EXIT)    
    {            
        menu_destroy(menu)    
        return PLUGIN_HANDLED    
    }    
     
    if(item == (sizeof Models))    
        cs_reset_user_model(id)  
    else { 
     
        client_print(id, print_chat, "Elegiste %s", Models[item]) 
        cs_set_user_model(id, Models[item]) 
         
    } 
     
    menu_destroy(menu)    
    return PLUGIN_HANDLED    
} 


[kikizon2]

Esto funciona si ya tienes tu plugin de skins de admin, solo compilas y pruebas...

Código PHP:

#include <amxmodx>
#include <cstrike>

new g_iActive[33], g_szStoredModel[33][128];

public plugin_init()
{
    register_plugin("ANON ADMIN", "0.1", "kikizon / LSSTUDIOS.XYZ");
    
    register_clcmd("say /anon", "clcmd_anon");
}

public client_putinserver(index) g_iActive[index] = false;

public clcmd_anon(index)
{
    new CsTeams:team = cs_get_user_team(index);
    if(~get_user_flags(index) & ADMIN_KICK || team == CS_TEAM_UNASSIGNED || team == CS_TEAM_SPECTATOR) return PLUGIN_HANDLED;

    g_iActive[index] = !g_iActive[index];

    if(g_iActive[index])
    {
        cs_get_user_model(index, g_szStoredModel[index], charsmax(g_szStoredModel[]));

        switch(team)
        {
            case CS_TEAM_CT: cs_set_user_model(index, "sas");
            case CS_TEAM_T: cs_set_user_model(index, "guerilla");
        }
    }
    else cs_set_user_model(index, g_szStoredModel[index]);

    client_print(index, print_chat, "[LSSTUDIOS] Ahora tu model es un model %s", g_iActive[index] ? "normal":"de admin");
    return PLUGIN_HANDLED;
} 


[rojedafeik]

Esto funciona si ya tienes tu plugin de skins de admin, solo compilas y pruebas...

Código PHP:

#include <amxmodx>
#include <cstrike>

new g_iActive[33], g_szStoredModel[33][128];

public plugin_init()
{
    register_plugin("ANON ADMIN", "0.1", "kikizon / LSSTUDIOS.XYZ");
    
    register_clcmd("say /anon", "clcmd_anon");
}

public client_putinserver(index) g_iActive[index] = false;

public clcmd_anon(index)
{
    new CsTeams:team = cs_get_user_team(index);
    if(~get_user_flags(index) & ADMIN_KICK || team == CS_TEAM_UNASSIGNED || team == CS_TEAM_SPECTATOR) return PLUGIN_HANDLED;

    g_iActive[index] = !g_iActive[index];

    if(g_iActive[index])
    {
        cs_get_user_model(index, g_szStoredModel[index], charsmax(g_szStoredModel[]));

        switch(team)
        {
            case CS_TEAM_CT: cs_set_user_model(index, "sas");
            case CS_TEAM_T: cs_set_user_model(index, "guerilla");
        }
    }
    else cs_set_user_model(index, g_szStoredModel[index]);

    client_print(index, print_chat, "[LSSTUDIOS] Ahora tu model es un model %s", g_iActive[index] ? "normal":"de admin");
    return PLUGIN_HANDLED;
} 


Muchas gracias kikizon! Ha funcionado perfecto