No Retry Plugin

[diegosm120]

saludos muchachos estoy buscando un plugin que cuando un usuario salga no lo dejen entrar por 60 segundos al servidor con la misma ip se podria hacer?

[JDAMPV]

Código PHP:

#include <amxmodx>

/* ===========================================================================​=============================
 *         [ Plugin initiation ]
 * ===========================================================================​===========================*/
 
#define IsUserAdmin(%1) ( get_user_flags( %1 ) & ADMIN_KICK )

const RETRY_DURATION = 60;

new Trie:g_tPlayer;

public plugin_init( )
{
    register_plugin( "Anti retry","1.0b","Manu" );
    
    g_tPlayer = TrieCreate( );
}

public plugin_end( )
    TrieDestroy( g_tPlayer );

/* ===========================================================================​=============================
 *         [ Functions ]
 * ===========================================================================​===========================*/

public client_putinserver( iId )
{
    static szIp[ 22 ],iTime; get_user_ip( iId,szIp,charsmax( szIp ),1 );
    
    if( TrieKeyExists( g_tPlayer,szIp ) )
    {
        TrieGetCell( g_tPlayer,szIp,iTime );
        
        if( get_systime( ) < iTime )
            server_cmd( "kick #%d ^"Tiempo de esperA: %d segundos ]^"",get_user_userid( iId ),iTime - get_systime( ) );
        else
            TrieDeleteKey( g_tPlayer,szIp );
    }
}

public client_disconnect( iId )
{
    if( IsUserAdmin( iId ) )
        return;
    
    static szIp[ 22 ]; get_user_ip( iId,szIp,charsmax( szIp ),1 );
    
    if( !TrieKeyExists( g_tPlayer,szIp ) )
        TrieSetCell( g_tPlayer,szIp,get_systime( ) + RETRY_DURATION );
} 


[diegosm120]

esto seria con la misma ip o el id?

[mlibre]

esto seria con la misma ip o el id?

get_user_ip