[TUT] Como crear entidades [ENGINE]

[I'mBuggimen]

solo te dare un ejemplo no lo testee pero deberia darte una idea de como hacerla

Código PHP:

#include <amxmodx>
#include <engine>

/* C Style */
#pragma semicolon 1

public plugin_init( )
{
    register_clcmd( "say /do", "LanzarEntidadExplosiva" );

    register_think( "FlyingEnt", "CBaseEntity_Think" ); // Registramos la fordward que no dara a saber cuando nuestra entidad piensa
}

public LanzarEntidadExplosiva( const iIndex )
{
    // Variable estatica para obtener el index de la entidad creada y setearle las configuraciones    
    static iEnt;    
        
    // SI cuando creamos la entidad esta es valida
    if( is_valid_ent( ( iEnt = create_entity( "info_target" ) ) ) )
    {
        static Float:vecUtil[ 3 ]; // variable estatica tipo Float (decimal) para obtener vectores

        // obtenemos los vectores dela posicion en la cual estas
        entity_get_vector( iIndex, EV_VEC_origin, vecUtil ); 

        // seteamos la posicion de nuestra entidad con los valores antes obtenidos
        entity_set_origin( iEnt, vecUtil );

        // seteamos que tu seas el dueño de esta entidad...
        entity_set_edict( iEnt, EV_ENT_owner, iIndex );

        // obtenemos la velocidad en la direccion que el jugador apunta y le multiplicamos 1000 en velocidad 
        velocity_by_aim( iIndex, 1000, vecUtil );

        // seteamos la velocidad obtenida 
        entity_set_vector( iEnt, EV_VEC_velocity, vecUtil );

        // seteamos un tipo de movimiento que atraviese las paredes
        // info: Este movetype no tiene colision por ende no podras chequear si colisiona con alguna entidad
        entity_set_int( iEnt, EV_INT_movetype, MOVETYPE_NOCLIP );

        // seteamos el solido a BBOX (tipo bloque)
        entity_set_int( iEnt, EV_INT_solid, SOLID_BBOX );

        // le seteamos un nombre que va caracterizar nuesta entidad de las demas
        entity_set_string( iEnt, EV_SZ_classname, "FlyingEnt" );

        // Seteamos en tiempo en que setea en este caso la entidad piensa cada 0.2 segundos
        entity_set_float( iEnt, EV_FL_nextthink, get_gametime( ) + 0.2 );
    }
}


public CBaseEntity_Think( const iEnt )
{
    // Esta entidad no es valida ?
    if(!is_valid_ent( iEnt ))
        return;

    static iDistance; // variable estatica para medir la distancia entre el Owner (Dueño de la entidad) y la Entidad
    static iOwner; // variable estatica para obtener el owner(Dueño de la entidad)

    iOwner = entity_get_edict( iEnt, EV_ENT_owner ); // obtenemos el owner(Dueño de la entidad)
    iDistance = get_entity_distance( iOwner, iEnt ); // Distancia entre Owner y Entidad

    if( iDistance >= 700 ) // si la distancia entre estos es mayor o igual a 700
    {
        Explosion( iEnt ); // Explosion
        remove_entity( iEnt );    // Removemos la entidad
    }

    entity_set_float( iEnt, EV_FL_nextthink, get_gametime( ) + 0.5 );    // si no ha explotado aun seteamos que piense cada 0.5 segundos mas
}

public Explosion(const iObject)
{
    // esto te lo explique al principio
    static iEnt;
    iEnt = create_entity("env_explosion");

    if(!iEnt) // Entidad no tiene index ?
        return 0; // retornamos 0;

    static Float:vecOrigin[3]; 
    entity_get_vector(iObject, EV_VEC_origin, vecOrigin); // obtener origin

    entity_set_vector(iEnt, EV_VEC_origin, vecOrigin); // Setear origin

    // Este es el Key Value de la entidad env_explosion que es la magnitud modifica el numero en el string( cadena de texto )
    DispatchKeyValue(iEnt, "iMagnitude", "200"); 

    // le indicamos que cuando la entidad que explota aparesca esta no pueda infligir daño
    entity_set_int(iEnt, EV_INT_spawnflags, SF_ENVEXPLOSION_NODAMAGE);

    // Spawneamos (Revivimos o hacemos aparecer) la entidad
    DispatchSpawn(iEnt);

    // Forzamos el uso de la entidad para que explote
    force_use(iEnt, iEnt);

    // la removemos ya que lo la usamos 
    // no tengo claro si es necesario hacer esto puesto que no se si esta al explotar se elimina automatica mente
    remove_entity(iEnt);

    // return 1;
    return 1;
} 


[josue9243]

Bien el tutorial aunque algunas cosas no las explicas bien ni cada funcion como deberia he intentado crear una entidad que se lanze desde el jugador y que explote si esta muy lejos y que pueda atravesar paredes. Gracias

En este tutorial esta lo basico tenés que ir armando, yo posteo esto por si alguien le ayuda, no me interesa si esta completo o no, porque esto que posteo es lo que me artaba de buscar y me costaba conseguir.

Lo tuyo es porque sos noob

Simplemente haces una entidad, lo adheris al prethink del jugador o haces un task con 0.000001 asi es mas fluido, tomas el origin del jugador y lo pones en la entidad.

[cl0ver]

Bueno Gracias a los 2 ire a probar...

[OsweRRR]

Quede arruinado con este tutorial, iré mejor a amxx-eng

EDIT; Hay cosas que no entiendo, siquiera se por donde iniciar

[CrazY.]

remove_entity_name is a good choice to remove all entities with the same name, only a hint.

[Hinami]

entonces como detecto que la entidad ya murió?

Código PHP:

if(!g_reg) 
    { 
        RegisterHamFromEntity(Ham_TakeDamage, ent, "fw_takedmg", 1) 
        RegisterHamFromEntity(Ham_Think, ent, "fw_think") 
        g_reg = 1 
    } 


un plugin que baje tiene eso, pero luego de leer los comentarios de metal quisiera saber como le detecto la muerta a la entidad

[Pan Bimbo (?]

entonces como detecto que la entidad ya murió?

Código PHP:

if(!g_reg) 
    { 
        RegisterHamFromEntity(Ham_TakeDamage, ent, "fw_takedmg", 1) 
        RegisterHamFromEntity(Ham_Think, ent, "fw_think") 
        g_reg = 1 
    } 


un plugin que baje tiene eso, pero luego de leer los comentarios de metal quisiera saber como le detecto la muerta a la entidad

y fijate...

Agarra el ent y chequeas la vida de la entidad, si querés que vea pasame el code completo, no vas a pretender que haga magia.

[Hinami]

a perdón ya lo había logrado, gracias igual