Detectar si es colocado en suelo [ORIGIN]

[I'mBuggimen]

hola, lo que quiero es saber como podria detectar si es colocado en el suelo 'x' Sprite.

pasa que se puede colocar en paredes y entre otras cosas yo quiero es que solo sea valido colocarlo en el suelo.

como podría llegar a ala solución ?

Tengo esto

Código PHP:

public showMenu_Line(const iIndex)
{
    static iMenu;

    iMenu = menu_create("TEST LINE", "hm_Line");

    menu_additem(iMenu, "Apuntar y Colocar Linea");

    menu_display(iIndex, iMenu);
}

public hm_Line(const iIndex, const iMenu, const iItem)
{
    if(iItem == MENU_EXIT || !is_user_alive(iIndex))
    {
        menu_destroy(iMenu);
        return PLUGIN_HANDLED;
    }

    static AimOrigin[3];
    get_user_origin(iIndex, AimOrigin, 3);

    // SI LO COLOCO EN EL SUELO EJECUTAMOS LO DE ABAJO 
    showLine(AimOrigin);
    
    menu_destroy(iMenu);
    return PLUGIN_HANDLED;
}

public showLine(const fOrigin[3])
{
    message_begin(MSG_BROADCAST, SVC_TEMPENTITY);
    write_byte(TE_BEAMPOINTS);

    write_coord(fOrigin[0]);
    write_coord(fOrigin[1]);
    write_coord(fOrigin[2]);
    write_coord(fOrigin[0]);
    write_coord(fOrigin[1]);
    write_coord(fOrigin[2] + 36);
    write_short(g_Beam);
    write_byte(0);    
    write_byte(0);        
    write_byte(60);        // Life    
    write_byte(15);        
    write_byte(0);    
    write_byte(0);        
    write_byte(200);    
    write_byte(0);
    write_byte(200);            
    write_byte(0);    
    message_end();
} 


Gracias de antemano si pueden dejar código mucho mejor.

[KISKE]

No se entiende muy bien que es lo que querés hacer.
Querés saber si el usuario está apuntando hacia el suelo ?

[I'mBuggimen]

en efecto saber que si obtengo los siguientes origins:

Código PHP:

static AimOrigin[3];
    get_user_origin(iIndex, AimOrigin, 3); 


estos no sean tomados de las paredes solo del suelo.

[Manu]

Código PHP:

#include <amxmodx>
#include <fakemeta>
#include <xs>
#include <engine>

public plugin_init( )
{
    register_plugin( "Test", "1.0", "Manu" );
    
    register_clcmd( "say /test", "cmdTest" );
}

public cmdTest( const iId )
{
    static iTrace, Float:flFraction, Float:flOrigin[ 3 ], Float:flAngles[ 3 ], Float:flNormal[ 3 ], Float:flViewOfs[ 3 ], Float:flEnd[ 3 ];
    
    iTrace = create_tr2( );
    
    entity_get_vector( iId, EV_VEC_origin, flOrigin );
    entity_get_vector( iId, EV_VEC_v_angle, flAngles );
    entity_get_vector( iId, EV_VEC_view_ofs, flViewOfs );
    
    xs_vec_add( flOrigin, flViewOfs, flOrigin );
    
    angle_vector( flAngles, ANGLEVECTOR_FORWARD, flAngles );
    
    xs_vec_mul_scalar( flAngles, 192.0, flAngles );
    xs_vec_add( flOrigin, flAngles, flEnd );
    
    engfunc( EngFunc_TraceLine, flOrigin, flEnd, DONT_IGNORE_MONSTERS, iId, iTrace );
    
    get_tr2( iTrace, TR_flFraction, flFraction );
    get_tr2( iTrace, TR_vecPlaneNormal, flNormal );
    
    free_tr2( iTrace );
    
    if( flFraction < 1.0 && flNormal[2] >= 0.9 )
    {
        client_print( iId, print_chat, "Estas apuntando al piso" );
    }
    
    return PLUGIN_HANDLED;
} 


[I'mBuggimen]

@Treki
Gracias es lo mas cercano que he conseguido, pero no me detecta si miro al suelo a una distancia larga.
imagino que es imposible hacer esto...

[josue9243]

@Treki
Gracias es lo mas cercano que he conseguido, pero no me detecta si miro al suelo a una distancia larga.
imagino que es imposible hacer esto...

La unica pendejada que se me ocurre es crear una o varias entidades que abarquen el suelo y detectarlo con el get_user_aiming.

[Manu]

@Treki
Gracias es lo mas cercano que he conseguido, pero no me detecta si miro al suelo a una distancia larga.
imagino que es imposible hacer esto...

Código PHP:

xs_vec_mul_scalar( flAngles, 192.0, flAngles ); 


Es porque tiene un límite de distancia... Subilo a 9999.0 si querés.