Forma correcta de forzar jointeam + Galileo Fix

[RauliTop]

Bueno, hace ya tiempo me pasó que utilizaba el plugin galileo (https://forums.alliedmods.net/showthread.php?t=77391) en un servidor y cuando llegaba la hora del vote, solo le salía el menú a algunos pocos.

Así que decidí investigarlo y me dí cuenta de que solo salía el menú a aquellos que antes del vote habían abierto algún menú cualquiera.

Lo primero fue ver en el plugin galileo porque pasaba esto y vi estas líneas:

Código PHP:

get_user_menu(id, menuid, menukeys);
if (menuid == 0 || menuid == g_menuChooseMap)
{
    show_menu(id, allKeys, menuDirty, max(1, g_voteDuration), MENU_CHOOSEMAP);
} 


que hace esto? simplemente get_user_menu devuelve el valor del menú que estás viendo, si no estás viendo ninguno es 0.
vale, como vemos en el chequeo, si te devuelve 0 o te devuelve el mismo menú del vote, se vuelve a mostrar.

entonces, lo que hice fue un simple plugin en el cual me decía si tenía un menú abierto o no utilizando get_user_menu. para mi sorpresa me encontré con que me decía que si, a pesar de que no tuviera ninguno abierto claro, y esto SOLO me pasaba después de ingresar al juego a través de un sistema de cuentas.
y también me di cuenta de que si yo abría un menu cualquiera, como el de admin, al cerrarlo me decía que no tenía ningún menú abierto.

viendo esto: http://www.amxmodx.org/funcwiki.php?go=func&id=1389
dije, mm.. asi que un VGUI menu tambien lo detecta get_user_menu, y efectivamente chequeando que el resultado de get_user_menu fuera negativo con el plugin que hice, me di cuenta que la culpa era de un VGUI menu que se me quedaba abierto después de "loguearme" en el servidor.

Pues vale, ya está, esto es culpa de forzar el jointeam de esta forma:

Código PHP:

static teammsg_block, teammsg_block_vgui
teammsg_block = get_msg_block(g_msgShowMenu)
teammsg_block_vgui = get_msg_block(g_msgVGUIMenu)
set_msg_block(g_msgShowMenu, BLOCK_ONCE)
set_msg_block(g_msgVGUIMenu, BLOCK_ONCE)
engclient_cmd(id, "jointeam", "5")
engclient_cmd(id, "joinclass", "5")
set_msg_block(g_msgShowMenu, teammsg_block)
set_msg_block(g_msgVGUIMenu, teammsg_block_vgui) 


esa es la forma correcta de forzar jointeam sin que te aparezca ningún menú de elegir apariencia ni nada del cs default.

vale, pues el problema era ahí, utilizando esa forma, se quedaba el offset m_iVGUI activo, así que:

Código PHP:

static teammsg_block, teammsg_block_vgui, restore, vgui
restore = get_pdata_int(id, 510) // m_iVGUI = 510
vgui = restore & (1<<0)
if (vgui) set_pdata_int(id, 510, restore & ~(1<<0))
teammsg_block = get_msg_block(g_msgShowMenu)
teammsg_block_vgui = get_msg_block(g_msgVGUIMenu)
set_msg_block(g_msgShowMenu, BLOCK_ONCE)
set_msg_block(g_msgVGUIMenu, BLOCK_ONCE)
engclient_cmd(id, "jointeam", "5")
engclient_cmd(id, "joinclass", "5")
set_msg_block(g_msgShowMenu, teammsg_block)
set_msg_block(g_msgVGUIMenu, teammsg_block_vgui)
if (vgui) set_pdata_int(id, 510, restore) 


de esta forma, evitamos que el offset se quede activo y get_user_menu nos devuelva true cuando no estamos con ningún menú.

aclaro que las variables globales creadas son en plugin_init:

Código PHP:

g_msgShowMenu = get_user_msgid("ShowMenu")
g_msgVGUIMenu = get_user_msgid("VGUIMenu") 


Esto fue todo, gracias

pd: la forma de "desactivar" ese offset la saqué del jailbreak de joropito
pd2: este error, obviamente, también se puede comprobar en otros plugins que utilicen get_user_menu

[roccoxx]

o.O interesante

[3mcy daimon't]

Es algo parecido a cuando abres un menu que no se puede cerrar con MEXIT_NEVER y escribes algun comando en say para abrir otro menu este no se abre...


PD: Buen aporte

[xPecie]

Gracias por tu tutorial!

[NikKOo31]

Tal vez parezca una pregunta tonta pero, porqe usas 4 var estáticas?

[RauliTop]

Tal vez parezca una pregunta tonta pero, porqe usas 4 var estáticas?

te refieres a por qué hay 4 o a por qué son estáticas?

[NikKOo31]

te refieres a por qué hay 4 o a por qué son estáticas?

Lo segundo ._.
Es necesario qe sean estáticas? ^^

[ivan]

GRABO RAULITOP TE VOTO GRACIAS RAUL ._.

[RauliTop]

te refieres a por qué hay 4 o a por qué son estáticas?

Lo segundo ._.
Es necesario qe sean estáticas? ^^

no, pero al ser una función que se va a llamar cuando alguien se loguea (es decir, bastantes veces), pues es conveniente que sean estáticas ya que son más rápidas

[NikKOo31]

Ya que estamos otra pregunta

Que estoy haciendo mal aqui?

Código PHP:

public ForzarJointeam(params[], id)
{
    server_print("forzarjointeam t:%d", params[0])
    static teammsg_block, teammsg_block_vgui, restore, vgui, szteam[3], szclass[3], team
    team = params[0]
    restore = get_pdata_int(id, 510) // m_iVGUI = 510
    vgui = restore & (1<<0)
    if(vgui)
    {
        set_pdata_int(id, 510, restore & ~(1<<0))
    }

    teammsg_block = get_msg_block(g_msgShowMenu)
    teammsg_block_vgui = get_msg_block(g_msgVGUIMenu)
    set_msg_block(g_msgShowMenu, BLOCK_ONCE)
    set_msg_block(g_msgVGUIMenu, BLOCK_ONCE)
    szteam[0] = team + '0'
    szteam[1] = 0
    szclass[0] = '5'
    szclass[1] = 0
    engclient_cmd(id, "jointeam", szteam)
    if(team != 6)
    {
        engclient_cmd(id, "joinclass", szclass)
    }
    set_msg_block(g_msgShowMenu, teammsg_block)
    set_msg_block(g_msgVGUIMenu, teammsg_block_vgui)
    if(vgui)
    {
        set_pdata_int(id, 510, restore) 
    }
} 


La idea principal es enviar a spec si la ronda ya esta empezada. Me bloquea el menu y en la consola sale:

forzarjointeam t:6

Pero me quedo en unassigned. Ya probe con y sin task y nada

[LeiToH]

Justo hoy me paso una situación asi , no le di mucha bola . Lo saque para depues testear
Interesante voy a ver que onda

[RauliTop]

La idea principal es enviar a spec si la ronda ya esta empezada. Me bloquea el menu y en la consola sale:

forzarjointeam t:6

Pero me quedo en unassigned. Ya probe con y sin task y nada

cuando llamas a esa función?

estás seguro que sigues siendo unassigned, hiciste un print o algo?

edit: acabo de probar el código de tu forma, igual las variables y todo y sí que me funciona.

[NikKOo31]

Estoy seguro que me deja unassigned, no puedo espectear a nadie, solo me deja mirar las "cámaras del mapa" y no puedo moverme ni abrir el menu de spec con el ctrl. Tmb me fije desde el team menu, y si me paso manualmente quedo bugueado y no tengo crosshair ._."

Código PHP:

    register_message(g_msgShowMenu = get_user_msgid("ShowMenu"),"MessageShowMenu")
    register_message(g_msgVGUIMenu = get_user_msgid("VGUIMenu"), "MessageVGUIMenu")

//...
public MessageVGUIMenu(msgId, dest, id)
{
    if(is_user_connected(id) && get_msg_arg_int(VGUIMENU_ARG_MENUID) == VGUIMENU_MENUID_TEAMSELECT && round_started)
    {
        //server_print("message vgui menu handled")
        new params[1]
        params[0] = 6
        set_task(0.1, "ForzarJointeam", id, params, sizeof params)
        return PLUGIN_HANDLED
    }
    //server_print("message vgui menu continue")
    return PLUGIN_CONTINUE
}

public MessageShowMenu(msgId, dest, id)
{
    new menuCode[32]
    get_msg_arg_string(4, menuCode, charsmax(menuCode))

    if(containi(menuCode, "Team_Select") > 0 && round_started)
    {
        //server_print("message show menu handled")
        new params[1]
        params[0] = 6
        set_task(0.1, "ForzarJointeam", id, params, sizeof params)
        return PLUGIN_HANDLED
    }
    //server_print("message show menu continue")
    return PLUGIN_CONTINUE
} 


Me siento idiota
Perdón por joder tanto

[Destro]

Tenes puesto allow_spectators 1 ?

[NikKOo31]

Tenes puesto allow_spectators 1 ?

Sipi

[Destro]

Que raro o.O

Ayer cuando lo probé y me paso lo mismo pero era porque tenia el hlds default con allow_spectators en 0.

[NikKOo31]

Que raro o.O

Ayer cuando lo probé y me paso lo mismo pero era porque tenia el hlds default con allow_spectators en 0.

Lo acabo de probar en un server hosteado y anda
Será problema de mi dedicado

Sorry por todo el spameo D:

[Destro]

Para prevenir "Only 1 team change is allowed."

Código PHP:

const m_iVGUI = 510
const m_bools125 = 125
const m_bHasChangeTeamThisRound = (1<<8)

/*
team:
 -0: AUTO
 -1: TT
 -2: CT
 -3: SPECT
free_changeteam:
  true: habilita el cambio de team en esa ronda
  false: (Only 1 team change is allowed.) 
*/
stock force_jointeam(id, team, free_changeteam)
{
    new param[2];param[0] = team;param[1] = free_changeteam;
    set_task(0.3, "task_jointeam", id, param, 2)
}

public task_jointeam(param[], id)
{
    static restore, bool25, vgui
    static const str_teams[][] = { "5", "1", "2", "6" }
    
    restore = get_pdata_int(id, m_iVGUI)
    vgui = restore & (1<<0)
    if(vgui) set_pdata_int(id, m_iVGUI, restore & ~(1<<0))

    bool25 = get_pdata_int(id, m_bools125)

    if(bool25 & m_bHasChangeTeamThisRound)
    {
        bool25 &= ~m_bHasChangeTeamThisRound
        set_pdata_int(id, m_bools125, bool25)
    }
    
    // No obtengo el bloqueo actual porque no hay ninguna razon para que un plugin bloquee estos mensajes globalmente. 
    set_msg_block(g_msgShowMenu, BLOCK_ONCE)
    set_msg_block(g_msgVGUIMenu, BLOCK_ONCE)

    engclient_cmd(id, "jointeam", str_teams[param[0]])
    if(param[0] != 3) engclient_cmd(id, "joinclass", "5")

    set_msg_block(g_msgVGUIMenu, BLOCK_NOT)
    set_msg_block(g_msgShowMenu, BLOCK_NOT)
    
    if(vgui) set_pdata_int(id, m_iVGUI, restore)
    if(param[1]) set_pdata_int(id, m_bools125, bool25)
}