Hacer tu propio chat

[RauliTop]

Bueno, en realidad no es que tuviera ganas de hacer esto pero viendo los tutoriales que hay por ahí... no ví ninguno de estos y los que ví están mal hechos. Por eso mismo me he propuesto hacer yo uno propio.

Sinceramente no sé si existe una forma mejor, simplemente yo utilizo esta y os la voy a enseñar. Es simple, es la forma que utiliza el admin chat colors.

Seguramente muchas veces habréis intentado hookear el say pero luego había incompatibilidad de plugins que hookean el say cada uno para su cosa y etc.
Pues aquí os enseño como crear el vuestro propio.

Código PHP:

// forward llamada cuando carga el plugin e inicia mapa (1 vez por mapa)
public plugin_init()
{
    // registramos los comandos que utiliza el cliente para mandar los mensajes que saldrán en el chat
    register_clcmd("say", "clcmd_say")
    register_clcmd("say_team", "clcmd_team_say")
}

// nuestro chat general se hace aquí
public clcmd_say(id)
{
    static said[191] // creamos la variable que servirá para almacenar todo nuestro string relacionado con el chat
    read_args(said, charsmax(said)) // obtenemos lo que escribimos (ej: say "hola soy yo") ahí obtenemos "hola soy yo"
    remove_quotes(said) // le quitamos las comillas al string
    replace_all(said, charsmax(said), "%", " ") // reemplazamos el % en caso de que alguien lo escriba para evitarnos el famoso bug
    
    // comprobamos que el mensaje sea válido, si no lo es para la función
    if (!ValidMessage(said, 1)) return PLUGIN_CONTINUE;
    
    // variable para almacenar el equipo (la utilizamos después) y otro string para añadir prefijos etc. a lo que dijimos
    static color[11], prefix[91]
    get_user_team(id, color, charsmax(color))
    
    // hacemos uso de nuestro string anterior
    // la primera variable servirá para saber si está vivo el jugador, si no tienen ninguna creada pues utilicen is_user_alive
    // la segunda variable es un ejemplo, por si quieren añadir más cosas, yo le puse el ejemplo de (VIP)
    // tercera variable seguro que la utilizan, la mayoría de los que quieren hacer esto con el chat es para mostrar el nivel de la persona que habla, ni falta decir que g_level es otro ejemplo
    // cuarta variable será el nombre del jugador, si no la tienen cacheada en una variable, pues tendrán que crear una aquí y utilizar get_user_name
    formatex(prefix, charsmax(prefix), "%s%s[Nivel:^x04 %d^x01]^x03 %s", g_isalive[id] ? "^x01" : "^x01*MUERTO* ", g_vip[id] ? "(VIP) " : "", g_level[id], g_playername[id])
    
    // formatex es más rápido, pero aquí conviene utilizar format para no tener que crear 1 variable de más
    // ahora chequeamos que si es admin/VIP (como ejemplo) le ponga lo que dice en verde
    if (is_user_admin(id) || g_vip[id]) format(said, charsmax(said), "^x04%s", said)
    // le añadimos el prefijo a lo que dijo para tenerlo todo en 1 solo string en vez de 2 por separado
    format(said, charsmax(said), "%s^x01 :  %s", prefix, said)
    
    static i, team[11] // variables que utilizaremos para el loop de jugadores, con team obtenemos su equipo porque hará falta cambiarlo para enviar el mensaje con el color correcto de equipo
    for (i = 1; i <= g_maxplayers; i++) // g_maxplayers es otro ejemplo de variable, su valor es get_maxplayers() cacheado en plugin_init
    {
        // otra variable cacheada, si no la tienen utilicen is_user_connected
        // si no está conectado el jugador del loop, paramos y seguimos con otro
        if (!g_isconnected[i]) continue;

        // pueden leer el mensaje que se escribió si:
        // es admin el jugador que lo recibirá
        // el que lo envió y el que lo recibirá están los dos vivos
        // el que lo envió y el que lo recibirá están los dos muertos
        // la variable g_isalive ya la expliqué anteriormente
        if (is_user_admin(i) || g_isalive[id] && g_isalive[i] || !g_isalive[id] && !g_isalive[i])
        {
            // obtenemos el equipo del que va a recibir el mensaje
            get_user_team(i, team, charsmax(team))
            // le cambiamos el equipo para que se muestre en el color correcto el ^x03
            changeTeamInfo(i, color)
            // le mandamos el mensaje
            writeMessage(i, said)
            // le dejamos el equipo como lo tenía antes
            changeTeamInfo(i, team)
        }
    }
    
    // importante para que funcionen otros plugins que hookeen el chat con comandos
    return PLUGIN_HANDLED_MAIN;
}

// nuestro chat de equipo se hace aquí
public clcmd_team_say(id)
{
    static said[191] // creamos la variable que servirá para almacenar todo nuestro string relacionado con el chat
    read_args(said, charsmax(said)) // obtenemos lo que escribimos (ej: say "hola soy yo") ahí obtenemos "hola soy yo"
    remove_quotes(said) // le quitamos las comillas al string
    replace_all(said, charsmax(said), "%", " ") // reemplazamos el % en caso de que alguien lo escriba para evitarnos el famoso bug
    
    // comprobamos que el mensaje sea válido, si no lo es para la función
    if (!ValidMessage(said, 1)) return PLUGIN_CONTINUE;

    // variable para almacenar el equipo (la utilizamos después) y otra variable en la cual le pondremos el nombre de equipo
    static playerTeam, playerTeamName[19]
    playerTeam = get_user_team(id)
    // según el equipo al que pertenezca le ponemos un nombre
    switch (playerTeam)
    {
        case 1: copy (playerTeamName, 6, "Holas") // T
        case 2: copy (playerTeamName, 8, "Adioses") // CT
        default: copy (playerTeamName, 11, "Espectador") // distinto de 1 y 2
    }
    
    // variable para almacenar el equipo (la utilizamos después) y otro string para añadir prefijos etc. a lo que dijimos
    static color[11], prefix[111]
    get_user_team(id, color, charsmax(color))
    
    // hacemos uso de nuestro string anterior
    // la primera variable servirá para saber si está vivo el jugador, si no tienen ninguna creada pues utilicen is_user_alive
    // la segunda variable es el equipo que pusimos antes
    // tercera variable seguro que la utilizan, la mayoría de los que quieren hacer esto con el chat es para mostrar el nivel de la persona que habla, ni falta decir que g_level es otro ejemplo
    // cuarta variable será el nombre del jugador, si no la tienen cacheada en una variable, pues tendrán que crear una aquí y utilizar get_user_name
    formatex(prefix, charsmax(prefix), "%s-%s- [Nivel:^x04 %d^x01]^x03 %s", g_isalive[id] ? "^x01" : "^x01*MUERTO* ", playerTeamName, g_level[id], g_playername[id])
    
    // formatex es más rápido, pero aquí conviene utilizar format para no tener que crear 1 variable de más
    // ahora chequeamos que si es admin/VIP (como ejemplo) le ponga lo que dice en verde
    if (is_user_admin(id) || g_vip[id]) format(said, charsmax(said), "^x04%s", said)
    // le añadimos el prefijo a lo que dijo para tenerlo todo en 1 solo string en vez de 2 por separado
    format(said, charsmax(said), "%s^x01 :  %s", prefix, said)
    
    static i, team[11] // variables que utilizaremos para el loop de jugadores, con team obtenemos su equipo porque hará falta cambiarlo para enviar el mensaje con el color correcto de equipo
    for (i = 1; i <= g_maxplayers; i++) // g_maxplayers es otro ejemplo de variable, su valor es get_maxplayers() cacheado en plugin_init
    {
        // otra variable cacheada, si no la tienen utilicen is_user_connected
        // si no está conectado el jugador del loop, paramos y seguimos con otro
        if (!g_isconnected[i]) continue;

        // es del mismo equipo, seguiremos chequeando a ver...
        if (get_user_team(i) == playerTeam)
        {
            // si el que envió el mensaje está vivo y él también, lo podrá leer
            // si el que envió el mensaje está muerto y él también, lo podrá leer
            if (g_isalive[id] && g_isalive[i] || !g_isalive[id] && !g_isalive[i])
            {
                // obtenemos el equipo del que va a recibir el mensaje
                get_user_team(i, team, charsmax(team))
                // le cambiamos el equipo para que se muestre en el color correcto el ^x03
                changeTeamInfo(i, color)
                // le mandamos el mensaje
                writeMessage(i, said)
                // le dejamos el equipo como lo tenía antes
                changeTeamInfo(i, team)
            }
        }
    }
    
    // importante para que funcionen otros plugins que hookeen el chat con comandos
    return PLUGIN_HANDLED_MAIN;
}

// esta función lo que hace es cambiar el equipo
// player es el index del jugador
// team es el equipo al que cambiará
public changeTeamInfo(player, team[])
{
    // importante que sea MSG_ONE, para asegurarnos de que se envía
    // g_msgTeamInfo es una variable chacheada en plugin_init cuyo valor es get_user_msgid("TeamInfo")
    message_begin(MSG_ONE, g_msgTeamInfo, _, player)
    write_byte(player)
    write_string(team)
    message_end()
}

// esta función enviará el mensaje por chat
// player es el index del jugador
// message será el mensaje (string) que se enviará
public writeMessage(player, message[])
{
    // importante que sea MSG_ONE, para asegurarnos de que se envía
    // g_msgSayText es una variable chacheada en plugin_init cuyo valor es get_user_msgid("SayText")
    message_begin(MSG_ONE, g_msgSayText, {0, 0, 0}, player)
    write_byte(player)
    write_string(message)
    message_end()
}

// Stock -counts number of characters in a string-
// es un stock que encontré por ahí y lo modifiqué un poco
stock ValidMessage(text[], maxcount) {
    static len, i, count
    len = strlen(text)
    count = 0
    
    if (!len)
        return false;
    
    for (i = 0; i < len; i++) {
        if (text[i] != ' ') {
            count++
            if (count >= maxcount)
                return true;
        }
    }
    
    return false;
} 


Para el chat recuerden:

Código:

^x01 -> color naranja o amarillo... según como lo vean (color default del chat)
^x04 -> color verde, aquí no soy daltónico
^x03 -> color del equipo

En fin, seguramente haya algo mal explicado o alguna cosa que me haya faltado, solo digan y se edita fácil

Saludos!

[[R]ak]

static i, team[11] // variables que utilizaremos para el loop de jugadores, con team obtenemos su equipo porque hará falta cambiarlo para enviar el mensaje con el color correcto de equipo

UNASSIGNED

edit: lo correcto es que saques todas esas variables "que si no tenes usa x"

[Avila]

Si apretan la "Y" para escribir por say y despues enter va aparecer esto:

NAMEPENE:

para que no aparesca nada:

Código PHP:

equal(szSay, "") || equal(szSay, " "))
        return PLUGIN_HANDLED 


[RauliTop]

static i, team[11] // variables que utilizaremos para el loop de jugadores, con team obtenemos su equipo porque hará falta cambiarlo para enviar el mensaje con el color correcto de equipo

UNASSIGNED

edit: lo correcto es que saques todas esas variables "que si no tenes usa x"

corregido, supongo que también habría que cambiar la variable color

lo preferible es cachear todas esas variables, y lo más seguro es que ellos las tengas cacheadas...
más de 1 vez he visto gente que las tiene cacheada y siguen utilizando is_user_alive o etc.

Si apretan la "Y" para escribir por say y despues enter va aparecer esto:

NAMEPENE:

para que no aparesca nada:

Código PHP:

equal(szSay, "") || equal(szSay, " "))
        return PLUGIN_HANDLED 


para algo está ValidMessage, no crees?

[mongito100]

Si apretan la "Y" para escribir por say y despues enter va aparecer esto:

NAMEPENE:

para que no aparesca nada:

Código PHP:

equal(szSay, "") || equal(szSay, " "))
        return PLUGIN_HANDLED 


No leíste o no entendiste si comprueba eso

Buen tut una cosa:
said[191]
Si no mal recuerdo el say tenia un máximo de 191 caract por ende no serian 192 posiciones para tener en cuenta el '^0'

[Avila]

static i, team[11] // variables que utilizaremos para el loop de jugadores, con team obtenemos su equipo porque hará falta cambiarlo para enviar el mensaje con el color correcto de equipo

UNASSIGNED

edit: lo correcto es que saques todas esas variables "que si no tenes usa x"

corregido, supongo que también habría que cambiar la variable color

lo preferible es cachear todas esas variables, y lo más seguro es que ellos las tengas cacheadas...
más de 1 vez he visto gente que las tiene cacheada y siguen utilizando is_user_alive o etc.

Si apretan la "Y" para escribir por say y despues enter va aparecer esto:

NAMEPENE:

para que no aparesca nada:

Código PHP:

equal(szSay, "") || equal(szSay, " "))
        return PLUGIN_HANDLED 


para algo está ValidMessage, no crees?

[cLAANS]

Lo mismo que dije en el otro TH, con eso puedo escribir en verde, azul y rojo e.e

Saludos,
cLAANS.-

[RauliTop]

Lo mismo que dije en el otro TH, con eso puedo escribir en verde, azul y rojo e.e

cómo? he probado poniendo ^x01 y los demás y no hace eso.

no entiendo a que te refieres...

[roccoxx]

Lo mismo que dije en el otro TH, con eso puedo escribir en verde, azul y rojo e.e

Saludos,
cLAANS.-

deja de hacerte el capo y decinos.

tambien comprate otro celu rata

[cLAANS]

lol, nunca me preguntaron -.-'.

Es un %s, pero el cs lo toma como un ^4 y otro que tambien es un %s como un ^3.

Lo que ahi, ay, hay, ayh, que hacer es bloquear los ^4 y ^3

Saludos,
cLAANS.-

[Metrikcz]

Si apretan la "Y" para escribir por say y despues enter va aparecer esto:

NAMEPENE:

para que no aparesca nada:

Código PHP:

equal(szSay, "") || equal(szSay, " "))
        return PLUGIN_HANDLED 


Con ese metodo solo pongo 2 espacios

[Avila]

Si apretan la "Y" para escribir por say y despues enter va aparecer esto:

NAMEPENE:

para que no aparesca nada:

Código PHP:

equal(szSay, "") || equal(szSay, " "))
        return PLUGIN_HANDLED 


Con ese metodo solo pongo 2 espacios

nope

[roccoxx]

Si apretan la "Y" para escribir por say y despues enter va aparecer esto:

NAMEPENE:

para que no aparesca nada:

Código PHP:

equal(szSay, "") || equal(szSay, " "))
        return PLUGIN_HANDLED 


Con ese metodo solo pongo 2 espacios

nope

deja de sumar post y comentar sin saber porque te vas a ganar mi negativo tambien.

[RauliTop]

lol, nunca me preguntaron -.-'.

Es un %s, pero el cs lo toma como un ^4 y otro que tambien es un %s como un ^3.

Lo que ahi, ay, hay, ayh, que hacer es bloquear los ^4 y ^3

Saludos,
cLAANS.-

todavía no entendí como harías para escribir de colores, de todas formas no importa mucho que alguien pueda escribir en colores

[mongito100]

No leíste mi msj

[Sangriento]

asi como esta puedo hacer una linda modificacion de mi config.cfg y escribir.

Sangriento: "hello boys" ( en verde o en otro color que quiera )

[roccoxx]

asi como esta puedo hacer una linda modificacion de mi config.cfg y escribir.

Sangriento: "hello boys" ( en verde o en otro color que quiera )

lo mismo que ima dijiste pelotudo, pone como lo harías para que raul pueda correjirlo, cuantas veces tengo que repetirlo?

[Metrikcz]

lol, nunca me preguntaron -.-'.

Es un %s, pero el cs lo toma como un ^4 y otro que tambien es un %s como un ^3.

Lo que ahi, ay, hay, ayh, que hacer es bloquear los ^4 y ^3

Saludos,
cLAANS.-

todavía no entendí como harías para escribir de colores, de todas formas no importa mucho que alguien pueda escribir en colores

^3, ^1 y ^4

[RauliTop]

No leíste mi msj

una letra menos no pasa nada

además, he visto mucho hook de say que le ponen menos de 100 celdas.
como lo tengo puesto (casi 200), no hacen faltan tantas en realidad porque los jugadores escriben mensajes largos y al final acaban utilizando 2 líneas de chat y creo que se duplicaba o pasaba algo raro

^3, ^1 y ^4

eso mismo probé ayer y no funcionaba, por eso dije que no entendía

de todas formas no importa mucho que alguien pueda escribir en colores

[Mía]

Hay una forma de hablar en verde, con una cfg mandas unos símbolos antes de las comillas y el remove_quotes no las remueve. Estos son los carácteres (Convertir a ASCII):

Código:

58 4 32

Y sigue un 34 (comillas) y el mensaje.

[Avila]

Si apretan la "Y" para escribir por say y despues enter va aparecer esto:

NAMEPENE:

para que no aparesca nada:

Código PHP:

equal(szSay, "") || equal(szSay, " "))
        return PLUGIN_HANDLED 


Con ese metodo solo pongo 2 espacios

nope

deja de sumar post y comentar sin saber porque te vas a ganar mi negativo tambien.

Le estoy respondiendo que no es así, que problema tenes?

PD: no me interesa sumar post

[Metrikcz]

Si apretan la "Y" para escribir por say y despues enter va aparecer esto:

NAMEPENE:

para que no aparesca nada:

Código PHP:

equal(szSay, "") || equal(szSay, " "))
        return PLUGIN_HANDLED 


Con ese metodo solo pongo 2 espacios

nope

deja de sumar post y comentar sin saber porque te vas a ganar mi negativo tambien.

Le estoy respondiendo que no es así, que problema tenes?

PD: no me interesa sumar post

Que si es asi
bloqueas: ""
bloqueas " "
pero 2 espacios != " ", es " "

[mongito100]

Para eso tendrias q copiar el texto a otra var hacerle un trim y ahy si verificar eso

[Avila]

Con ese metodo solo pongo 2 espacios

nope

deja de sumar post y comentar sin saber porque te vas a ganar mi negativo tambien.

Le estoy respondiendo que no es así, que problema tenes?

PD: no me interesa sumar post

Que si es asi
bloqueas: ""
bloqueas " "
pero 2 espacios != " ", es " "

Probalo y fijate no hablo mas..

[Mía]

Yo usaba así en mi sistema de chat...

Código PHP:

if (!said[0] || (said[0] == ' ' && (!said[1] || said[1] == ' ')))
    return PLUGIN_HANDLED; 


EDIT: Para evitar que hablen en color podemos usar esto en vez del remove_quotes

Código PHP:

stock un_mejor_remove_quotes(str[])
{
    static len; len = strlen(str);
    if (len <= 1)
        return 0;

    // No comprobamos que sea comilla, asi el maximo len siempre sera igual, con comilla o no
    str[--len] = EOS;
    for (new i = 0; i < len; i++)
    {
        if (str[i] == '"')
        {
            copy(str, len, str[++i])
            return len-i;
        }
    }

    return 0;
}