[INC] Steam Avatar

[[N]drs]

[INC] Steam Avatar

Descripción:
- Este include te permite obtener la url del avatar de los jugadores steam
- La ventaja de este INC frente a [API] Advanced STEAM v3.1, es que no necesitas instalar ningún otro plugin adicional para que este inc funcione

Requisitos:

• AmxModX 1.9.0
  
• Curl - El módulo y los includes para poder compilar
  
• Obtener tu ApiKey en la web de Steam
  

Resumen del inc:

Código PHP:

/**
 * Establece la ApiKey a usar para las solicitudes a Steam
 * @nota Si no se establece no podrás obtener el avatar 
 *
 * @param szApiKey         Tu ApiKey de Steam
 *
 * @noreturn
 */
stock set_steam_apikey(const szApiKey[])

/**
 * Solicita a Steam obtener el avatar de un jugador 
 *
 * @nota Estructura del handler (const szAvatartURL[], const bool:bError, const data[])
 *
 * @param szSteamID         SteamID del jugador
 * @param szHandlerFunc    Handler del petición a Steam
 * @param data                  Cualquier dato para pasar al hadler
 * @param len                    Tamaño máximo de los datos
 *
 * @noreturn
 * @error                  Si hay algún tipo de error durante la petición,
 * se mostrará el error en la consola del servidor
 */
stock get_steam_avatar(const szSteamID[], const szHandlerFunc[], const data[] = {}, const len = 0) 


Ejemplo de uso:

Código PHP:

#include <amxmodx>
#include <steam_avatar>

#define PLUGIN  "Ejemplo de uso de Steam Avatar"
#define VERSION "1.0"
#define AUTHOR  "[N]drs"

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)

    register_clcmd("say /avatar", "ShowAvatar")

    set_steam_apikey("TuSteamApiKeyAquí")
}

public ShowAvatar(id)
{
    new szSteamID[64], data[1]

    get_user_authid(id, szSteamID, charsmax(szSteamID))

    data[0] = id
    get_steam_avatar(szSteamID, "SteamHandler", data, 1)
}

public SteamHandler(const szAvatarURL[], const bool:bError, const data[])
{
    if(!bError)
    {
        server_print("ID: %d", data[0])
        server_print("AvatarURL: %s", szAvatarURL)
    }
} 


[samuelt]

Aportazo prro <3

[OsweRRR]

Creo que flys o un tal alejandro aportaron algo similar donde no solo obtenian el avatar del steam si no que otros datos mas. Amplia mas tu include, me gusta el metodo del callback, pero no usaria del todo el modulo curl, no hasta que le den el visto bueno los dev's de AMXX.

[[N]drs]

Creo que flys o un tal alejandro aportaron algo similar donde no solo obtenian el avatar del steam si no que otros datos mas. Amplia mas tu include, me gusta el metodo del callback, pero no usaria del todo el modulo curl, no hasta que le den el visto bueno los dev's de AMXX.

Mi inc está hecho únicamente para obtener solo el avatar y nada más sin necesidad de instalar otro plugin para que funcione

[Meliodas]

Buen aporte, como se haría para obtener la foto vía motd pero llamando la native en un public ya creada?

[GabsHp]

Buen aporte, como se haría para obtener la foto vía motd pero llamando la native en un public ya creada?

Almacenas el url en una string y la llamas desde el html del motd, tipo el motd del TTT. Esto hablando del caso en que el html lo tengas dentro del mismo plugin.

[OsweRRR]

Volvi a ver este include en un trabajo reciente y no pude evitar mejorarlo, me gusta la simplicidad y aun asi se puede ampliar a no solo obtener el avatar.

Código PHP:

get_steam_avatar("handle_steam", id, g_iPlayerStats[id][StatsId]) 


Código PHP:

public handle_steam(id, any:data, bool:error, avatarfull[])
{
    if(!error && strlen(avatarfull) > 0)
    {
        SQL_ThreadQuery(SQL_Tuple, "handle_query", fmt("UPDATE `stats_player` SET `userAvatar` = ^"%s^" WHERE `id_stats` = '%d';", avatarfull, data), {0, 3}, 2)
    }
} 


Código PHP:

#if !defined _curl_included
    #include <curl>
#endif

#if !defined _json_included
    #include <json>
#endif

#define MAX_HANDLER_LENGTH 32

new g_sJsonCode[1024], g_sApiKeySteam[40]

set_steam_apikey(const apikey[])
{
    format(g_sApiKeySteam, charsmax(g_sApiKeySteam), "%s", apikey)
}

stock get_steam_avatar(handler[MAX_HANDLER_LENGTH], id, any:data = 0)
{
    if(!is_user_bot(id) && !is_user_hltv(id))
    {
        new sBuffer[32]; get_user_authid(id, sBuffer, charsmax(sBuffer))
        
        if(containi(sBuffer, "STEAM_0:0") != -1 || containi(sBuffer, "STEAM_0:1") != -1)
        {
            new sTemp[MAX_HANDLER_LENGTH + 10], CURL:curl_handle = curl_easy_init()
            
            format(sTemp, charsmax(sTemp), "%i %i %s", id, data, handler)
            
            get_user_info(id, "*sid", sBuffer, charsmax(sBuffer))
            
            curl_easy_setopt(curl_handle, CURLOPT_BUFFERSIZE, sizeof g_sJsonCode)
            curl_easy_setopt(curl_handle, CURLOPT_URL, fmt("http://api.steampowered.com/ISteamUser/GetPlayerSummaries/v0002/?key=%s&steamids=%s&format=json", g_sApiKeySteam, sBuffer))
            curl_easy_setopt(curl_handle, CURLOPT_CUSTOMREQUEST, "GET")
            curl_easy_setopt(curl_handle, CURLOPT_WRITEFUNCTION, "curlWrite")
            
            curl_easy_perform(curl_handle, "curlComplete", sTemp, charsmax(sTemp))
        }
        else
        {
            executeForward(handler, id, data, true, "")
        }
    }
    else
    {
        executeForward(handler, id, data, true, "")
    }
}

public curlWrite(data[], size, nmemb)
{
    formatex(g_sJsonCode, size * nmemb, data)
    
    return size * nmemb
}

public curlComplete(CURL:curl, CURLcode:code, data[])
{
    new sHandler[MAX_HANDLER_LENGTH], sPlayerIndex[5], sAnyData[5], sAvatarFull[128], bool:bError = false
    
    parse(data, sPlayerIndex, charsmax(sPlayerIndex), sAnyData, charsmax(sAnyData), sHandler, charsmax(sHandler))
    
    curl_easy_cleanup(curl)
    
    if(code != CURLE_OK)
    {
        bError = true
    }
    else
    {
        new JSON:json_handle = json_parse(g_sJsonCode)
        
        if(json_handle != Invalid_JSON)
        {
            json_handle = json_object_get_value(json_handle, "response")
            json_handle = json_object_get_value(json_handle, "players")
            json_handle = json_array_get_value(json_handle, 0)
            
            if(json_handle == Invalid_JSON)
            {
                bError = true
            }
            else
            {
                json_object_get_string(json_handle, "avatarfull", sAvatarFull, charsmax(sAvatarFull))
                
                replace_string(sAvatarFull, charsmax(sAvatarFull), "https", "http")
            }
        }
        else
        {
            bError = true
        }
        json_free(json_handle)
    }
    executeForward(sHandler, str_to_num(sPlayerIndex), str_to_num(sAnyData), bError, sAvatarFull)
}

executeForward(handler[], id, any:data, error, avatarfull[])
{
    if(callfunc_begin(handler) == 1)
    {
        callfunc_push_int(id)
        callfunc_push_int(data)
        callfunc_push_int(error)
        callfunc_push_str(avatarfull)
        callfunc_end()
    }
} 


[MatiasGFaria]

Alguien me ayuda con este problema, me salió hace unos días en la consola del host.

[Rango_Top10.amxx] [INC] Steam Avatar > Json invalido, verifica tu Steam ApiKey

[[N]drs]

Alguien me ayuda con este problema, me salió hace unos días en la consola del host.

[Rango_Top10.amxx] [INC] Steam Avatar > Json invalido, verifica tu Steam ApiKey

Asegurate que tu steam apikey esté funcionando, o de lo contrario vuelve a crear otra en steam

[MatiasGFaria]

Cómo hago para saber si mi steam apikey está funcionando o crear otra en steam?

Pasa que me tira mucho error y me da tirones a mi servidor

[[N]drs]

Cómo hago para saber si mi steam apikey está funcionando o crear otra en steam?

Pasa que me tira mucho error y me da tirones a mi servidor

Obtener tu ApiKey en la web de Steam

[MatiasGFaria]

Obtener tu ApiKey en la web de Steam

El tema que funciona mal en mi servidor. me satura el server y me lo tira.

[Meliodas]

El tema que funciona mal en mi servidor. me satura el server y me lo tira.

Para que eso no sucede, haz lo de la apikey que te estan diciendo dios mio...

[[N]drs]

El tema que funciona mal en mi servidor. me satura el server y me lo tira.

En el plugin que te está dando problemas, busca la native: set_steam_apikey("TuSteamApiKeyAquí")
y ahi coloca la apikey que hayas generado