Menu de Admin sXe

[Mía]

sXe Admin Menu

Descipción del plugin

• Este plugin es sólo un par de menúes para los Admins, para hacer acciones del sXe Injected. Se lo envié a los de LocalStrike pero creo que ni lo vieron
  

Modo de uso (Comandos de chat)

• /sxescreen - Muestra un menú con todos los jugadores para sacarles un screen.
  
• /sxeban - Lo mismo que el screen, pero para local ban.
  

PD: En el archivo de logs se registra cada acción que haga algun admin con este plugin, sea screen o local ban.


v1.1:
- Agregado: Menú de confirmación antes de banear a un jugador.
v1.0:
- Versión inicial.

[K.-']

Que muestra en los Logs ?

Pd : mmmmm buen plugin

Saludos.

[Mía]

Que muestra en los Logs ?

Pd : mmmmm buen plugin

Saludos.

Gracias! Ya actualicé el post, revisa

[mongito100]

Yo sacaría el say de la const si me entendes por q por Ahy viene alguien q lo quiero modif y no entiende nada y no pone el say además de q es un plugin creo q podría ser por cvar
Me gusta la idea de manejar el sxe por menú en ves de cvars
Pd:no leí el code

[Mía]

Yo sacaría el say de la const si me entendes por q por Ahy viene alguien q lo quiero modif y no entiende nada y no pone el say además de q es un plugin creo q podría ser por cvar
Me gusta la idea de manejar el sxe por menú en ves de cvars
Pd:no leí el code

Tienes razón, ahora actualizo. El comando es para chat porque los admins necesitan rapidez para accesar al screen si sospechan de algun chitero.

[K.-']

Que muestra en los Logs ?

Pd : mmmmm buen plugin

Saludos.

Gracias! Ya actualicé el post, revisa

Hoara si . Exelente Plugin.

gracias por aportar

[Neeeeeeeeeel.-]

Es un plugin bastante simple, pero útil.

[Plaks]

Estaría bueno que te de una confirmación antes de banear a un usuario...

[Mía]

Estaría bueno que te de una confirmación antes de banear a un usuario...

Listo. Gracias por la sugerencia.

[Bolbec.-]

No sé si este tema está muerto, es que estaba viendo los aportes de Mario. Pero, Mario podrías agregarle también para que vean la HID de un jugador, o agregarle un Sistema propio de BAN por HID, con el tiempo, razón, etc.

[Mía]

No sé si este tema está muerto, es que estaba viendo los aportes de Mario. Pero, Mario podrías agregarle también para que vean la HID de un jugador, o agregarle un Sistema propio de BAN por HID, con el tiempo, razón, etc.

http://amxmodx-es.com/Thread-Ultimater-B...te-HID-Ban
http://amxmodx-es.com/Thread-APORTE-amx-hid

[RauliTop]

se refiere a que es mejor que lo agreges a este plugin, así sería más completo.

[Mía]

La intención del plugin es facilitar el uso del ban local y el screenshot porque los plugins default del sxe te hacen un lio en buscar el userid y todo eso, este plugin nos ahorra este trabajo. Ahora, implementarle un propio sistema de ban, si utiliza el de sxe? No le veo mucho sentido a eso, y si alguien quisiera eso puede utilizar el Ultimater. Y en el caso del HID, al menos a mi no me parece que un admin pueda tener una razón para guardarse el hid de un jugador.

[Evil Spiret]

lo veo util , gracias por aportarlo

[elquenoseregistro]

este plugin banea a los admin hasta los que tienen inmunidad y rcon
/sxeban

cambiar en el sma, sxe_ban por amx_sxe_ban

[MATiASc]

La verdad que genial, excelente trabajo! lo unico que si podes agregar es que si los comandos
/sxeban & /sxescreen funcionen con el amx apagado, porque para que sean funcional el amx tiene que estar encendido, seria una onda asi como el mixmaker, que cuando esta el amx_off podes poner /nonick & /nosay y habilita o deshabilita el cambio de nick o el say, desde ya muchisimas gracias por el aporte.!

Saludos.!

[Mía]

este plugin banea a los admin hasta los que tienen inmunidad y rcon
/sxeban

cambiar en el sma, sxe_ban por amx_sxe_ban

Este plugin no banea a nadie; lo hace el sXe

La verdad que genial, excelente trabajo! lo unico que si podes agregar es que si los comandos
/sxeban & /sxescreen funcionen con el amx apagado, porque para que sean funcional el amx tiene que estar encendido, seria una onda asi como el mixmaker, que cuando esta el amx_off podes poner /nonick & /nosay y habilita o deshabilita el cambio de nick o el say, desde ya muchisimas gracias por el aporte.!

Saludos.!

En tu amxx.cfg agrega esta línea:

Código:

amx_pausecfg add "sXe-I Admin Menu"

[MATiASc]

En tu amxx.cfg agrega esta línea:

Código:

amx_pausecfg add "sXe-I Admin Menu"

Hola gracias por responder. Ya edite el .sma y lo volvi a compilar, agregandole para que funcione con el amx apagado sin necesidad de editar el archivo amxx.cfg y tambien corregi un error que cuando escribias /sxescreen y se te abria el menu no decia [sXe-i] Screenshot, sino que decia y[sXe-i]r Screenshot, dejo el codigo del .sma si queres agregalo al primer post.

Código PHP:

#include <amxmodx>

// Name for the log file
new const LogFile[] = "sxei_admin_menu.txt"

// Chat commands to open the menus
new const Commands[2][] =
{
    "/sxeban",        // For the local ban menu
    "/sxescreen"        // For the screenshot menu
}

// ================================================================

new g_action, g_connected, g_maxplayers[1 char];

#define PLUGIN "sXe-I Admin Menu"
#define VERSION "1.2"

#pragma semicolon 1

#define set_action_localban(%0) (g_action |= (1 << %0-1))
#define clear_action_localban(%0) (g_action &= ~(1 << %0-1))
#define check_action_localban(%0) (g_action & (1 << %0-1))

#define set_player_connected(%0) (g_connected |= (1 << %0-1))
#define clear_player_connected(%0) (g_connected &= ~(1 << %0-1))
#define check_player_connected(%0) (g_connected & (1 << %0-1))

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, "Mario AR.");
    
    new buffer[100];
    
    formatex(buffer, charsmax(buffer), "say %s", Commands[0]);
    register_clcmd(buffer, "clcmd_localban", ADMIN_BAN);
    
    formatex(buffer, charsmax(buffer), "say %s", Commands[1]);
    register_clcmd(buffer, "clcmd_screen", ADMIN_BAN);
    
    register_dictionary("common.txt");
    
    g_maxplayers{0} = get_maxplayers();
}

public plugin_cfg()
{
    if(is_plugin_loaded("Pause Plugins") > -1)
        server_cmd("amx_pausecfg add ^"sXe-I Admin Menu^"");
}  

public client_putinserver(id)
    if (!is_user_bot(id)) set_player_connected(id);
    
public client_disconnect(id)
    clear_player_connected(id);

public clcmd_localban(id, level)
{
    if (~get_user_flags(id) & level)
        return PLUGIN_CONTINUE;
    
    set_action_localban(id);
    show_menu_players(id);
    
    return PLUGIN_HANDLED;
}

public clcmd_screen(id, level)
{
    if (~get_user_flags(id) & level)
        return PLUGIN_CONTINUE;
    
    clear_action_localban(id);
    show_menu_players(id);
    
    return PLUGIN_HANDLED;
}
    
show_menu_players(id)
{
    new szItem[32];
    formatex(szItem, charsmax(szItem), "\[sXe-I] \%s Menu", check_action_localban(id) ? "Local Ban" : "Screenshot");
    
    new menu = menu_create(szItem, "menu_players");

    new i, szUserID[8];

    for (i = 1; i < g_maxplayers{0}; i++)
    {
        if (!check_player_connected(i))
            continue;

        get_user_name(i, szItem, charsmax(szItem));
        
        num_to_str(get_user_userid(i), szUserID, charsmax(szUserID));

        menu_additem(menu, szItem, szUserID, 0);
    }
    
    formatex(szItem, charsmax(szItem), "%L", LANG_SERVER, "MORE");
    menu_setprop(menu, MPROP_NEXTNAME, szItem);
    
    formatex(szItem, charsmax(szItem), "%L", LANG_SERVER, "EXIT");
    menu_setprop(menu, MPROP_EXITNAME, szItem);
    
    formatex(szItem, charsmax(szItem), "%L", LANG_SERVER, "BACK");
    menu_setprop(menu, MPROP_BACKNAME, szItem);

    menu_display(id, menu);
}

public menu_players(id, menu, item)
{
    if (item == MENU_EXIT)
    {
        menu_destroy(menu);
        return PLUGIN_HANDLED;
    }
    
    new szData[8], player, userid;

    // We don't need &access and &callback, so we'll use player.
    menu_item_getinfo(menu, item, player, szData, charsmax(szData), _, _, player);
    
    userid = str_to_num(szData);
    player = find_player("k", userid);
    
    if (player)
    {
        if (check_action_localban(id))
            show_confirm_ban(id, player, szData);
        else
        {
            server_cmd("sxe_screen #%d #%d", userid, get_user_userid(id));
        
            new szName[2][32];
            get_user_name(id, szName[0], 31);
            get_user_name(player, szName[1], 31);
            
            log_to_file(LogFile, "%L %s - Screenshot %s", LANG_SERVER, "ADMIN", szName[0], szName[1]);
        }
    }
        
    menu_destroy(menu);
    return PLUGIN_HANDLED;
}

show_confirm_ban(id, player, szUserID[])
{
    new menu, szItem[50];
    
    // We're using 'menu' to store the len of string.
    menu = copy(szItem, charsmax(szItem), "\r[sXe-I]\y Local Ban\w ");
    menu += get_user_name(player, szItem[menu], charsmax(szItem)-menu);
    copy(szItem[menu], charsmax(szItem)-menu, "\y?");
    
    // Now 'menu' is the pointer of the menu.
    menu = menu_create(szItem, "confirm_ban");
    
    formatex(szItem, charsmax(szItem), "%L", LANG_SERVER, "YES");
    menu_additem(menu, szItem, szUserID);
    
    formatex(szItem, charsmax(szItem), "%L", LANG_SERVER, "NO");
    menu_additem(menu, szItem);
    
    menu_setprop(menu, MPROP_EXIT, MEXIT_NEVER);
    
    menu_display(id, menu);
}

public confirm_ban(id, menu, item)
{
    if (!item)
    {
        new szData[8], player, userid;

        // We don't need &access and &callback, so we'll use player.
        menu_item_getinfo(menu, item, player, szData, charsmax(szData), _, _, player);
        
        userid = str_to_num(szData);
        player = find_player("k", userid);
        
        if (player)
        {
            server_cmd("sxe_ban #%d", userid);
        
            new szName[2][32];
            get_user_name(id, szName[0], 31);
            get_user_name(player, szName[1], 31);
            
            log_to_file(LogFile, "%L %s - Local ban %s", LANG_SERVER, "ADMIN", szName[0], szName[1]);
        
            client_print(0, print_chat, "[sXe-I] %L %s - Local ban %s", LANG_SERVER, "ADMIN", szName[0], szName[1]);
        }
    }
    
    menu_destroy(menu);
    return PLUGIN_HANDLED;
}
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang10250\\ f0\\ fs16 \n\\ par }
*/ 


Saludos.!

[MATiASc]

Nuevamente yo, tengo un pequeño problema, tengo 3 servers de diferentes host, 1 lo pago los otros 2 son gratis (yo levante los 2 que son gratis para los dueños de los host y a cambio me dieron 1 server gratis todo el tiempo que dure el host) bien el problema esta en que en uno de los 2 servers que son gratis cuando pongo /sxescreen y saco una captura de pantalla me tira ban por "fake player" y en el otro no, en el que pasa esto, esta corriendo en linux y el otro en windows, ambos tiene los ultimos archivos de steamcmd y tienen corriendo los mismos plugins, tambien tienen la ultima versión del amx y metamod, alguna idea del porque el ban?

Saludos.!

[Kuzan]

A veces no aparecen algunos players en el menu, tengo el plugin totalmente default, se sabe por que puede ser? más allá de eso excelente aporte!

[problader]

!Hola!. Coloca el comando en consola sxe_screen y no funciona y creo que lo tiene registrado el plugin ese comando no?

[Hinami]

Modo de uso (Comandos de chat)

• /sxescreen - Muestra un menú con todos los jugadores para sacarles un screen.
  
• /sxeban - Lo mismo que el screen, pero para local ban.
  

pues creo que no, osea el plugin ejecuta ese comando, más no es un comando directamente de ese plugin.

[Nelo]

Código PHP:

#include <amxmodx>
#include <amxmisc>

const ADMIN_FLAG = ADMIN_BAN

public plugin_init()
{
    register_plugin("sXe Screenshot", "1.0", "payas")
    register_concmd("amx_sxe_screen", "cmd_screen", ADMIN_FLAG, "<name>")
}

public cmd_screen(id, level, cid)
{
    if (!cmd_access(id, level, cid, 2))
        return PLUGIN_HANDLED;

    new arg[32]
    read_argv(1, arg, 31)
    new target = cmd_target(id, arg, 0)

    //client_print(id, print_chat, "TEST %d", get_user_userid(id))

    if (!is_user_connected(target))
        return PLUGIN_HANDLED;

    if (is_user_bot(target))
    {
        client_print(id, print_chat, "[AMXX] %L", id, "BOT_MESSAGE")
        return PLUGIN_HANDLED;
    }

/****
    if (is_user_admin(target))
    {
        client_print(id, print_chat, "[AMXX] %L", id, "ADMIN_MESSAGE")
        return PLUGIN_HANDLED;
    }
***/
    server_cmd("sxe_screen #%d #%d", get_user_userid(target), get_user_userid(id))


    new nick1[32], nick2[32]
    get_user_name(id, nick1, 31)
    get_user_name(target, nick2, 31)

    //client_print(0, print_chat, "ADMIN %L", LANG_PLAYER, "LOCALBAN_MESSAGE", nick1, nick2)

    log_amx("ADMIN %L", LANG_SERVER, "ScreenShot for player [%s] to [%s]", nick1, nick2)

    return PLUGIN_HANDLED;
} 


Código PHP:

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "sXe Local Ban"
#define VERSION "1.0"
#define AUTHOR "Rul4"


public plugin_init() 
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    register_concmd("amx_sxe_ban", "sxeban", ADMIN_BAN);
}

public sxeban(id) 
{
    new Arg1[24];
  
    read_argv(1, Arg1, 23);
    new adminName[33];
    get_user_name(id,adminName,32);

    if(strlen(Arg1)!=0)
    {
        new uid = find_player("k",str_to_num (Arg1[1]));
        new plyrName[33];
        get_user_name(uid,plyrName,32);
        console_print(id, "sXe Injected: %s has locally banned player %s", adminName, plyrName);
        log_amx("sXe Injected: %s has locally banned player %s", adminName, plyrName);
    }

    server_cmd("sxe_ban %s", Arg1);
} 


[maxedrom]

me gustaria poner el sxe en mi servidor, pero no encuentro los files para poder instalarlo en mi seerver .(

[djsebass41]

no anda los link de compiladooo!