Menu de Brillo (SIMPLE)

[Nazy.-]

Que tal amigos, espero se encuentren bien, les voy a traer uno de los muchos plugins que hice durante mi baneo. Y por favor antes que nada quiero decir que se ahorren sus comentarios que no aportan nada bueno a este foro, tampoco quiero que me digan que he hecho copy-paste porque no lo he hecho así que... Cualquier comentario negativo y nada que ver ps ni lo voy a contestar

Este menú de brillo fue uno de los primeros plugins que hice aprendiendo a programar y toda esa verga, es simple, capaz les sirve para algún mod que tengan o quien sabe? Si ven algo in-necesario o algo que no este muy bien hecho me lo dicen! Créditos a totopizza que me dijo lo del item-1

Código PHP:

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <hamsandwich>
#include <fun>
#include <cc>

#define PLUGIN "Simple Glow Menu"
#define VERSION "1.0"
#define AUTHOR "Nazy.-"

#define GlowAmount 20 
// Definimos el grosor del glow, mientras mas sea el numero, mas fuerte sera el glow

enum _:DATA_GLOW
{
    NOMBRE[32],
    COLOR_R,
    COLOR_G,
    COLOR_B
}

new const GlowLista[][DATA_GLOW] = 
{
    /* Nombre  - R  - G  - B */
    { "Blanco", 255, 255, 255},
    { "Verde", 0, 255, 10},
    { "Rojo", 255, 10, 0},
    { "Rosado", 200, 0, 200 },
    { "Verde Slime", 66, 245, 147 },
    { "Azul Mar", 66, 156, 245 },
    { "Purpura", 111, 66, 245 },
    { "Fuxia", 245, 66, 123 },
    { "Rojo Sangre", 245, 66, 66 },
    { "Arcilla", 79, 71, 61 },
    { "Verde Lima", 146, 255, 69 }
}

new g_GlowSelected[33];

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_clcmd("say /glowmenu", "cmd_glowmenu")
    RegisterHam(Ham_Spawn, "player", "fw_PlayerSpawnPost", 1)
}
public cmd_glowmenu(id) {
    
    new menu = menu_create("Menu de Glow", "gm_handler")
    
    menu_additem(menu, "\yREMOVER BRILLO")
    
    for(new i = 0; i < sizeof(GlowLista); i++) menu_additem(menu, GlowLista[i][NOMBRE]);
    
    menu_display(id, menu, 0)
    return PLUGIN_HANDLED;
}
public client_putinserver(id) g_GlowSelected[id] =-1
public gm_handler(id, menu, item) {
    
    if(item == 0) {
        if(!g_GlowSelected[id]) colorChat(id, print_chat, "!g[GLOW] !yTu no tienes un brillo seleccionado")
        set_user_rendering(id)
        colorChat(id, print_chat, "!g[GLOW] !yTu brillo fue removido!")
    } else {
    
    if(is_user_alive(id)) { 
        if(g_GlowSelected[id] == item-1) return PLUGIN_HANDLED;
                
        g_GlowSelected[id] = item-1
        set_user_rendering(id, kRenderFxGlowShell, GlowLista[item-1][COLOR_R], GlowLista[item-1][COLOR_G], GlowLista[item-1][COLOR_B], kRenderNormal, GlowAmount)
        colorChat(id, print_chat, "!g[GLOW] !yHas elegido el color !g%s!y!", GlowLista[item-1][NOMBRE])
    }
}
    return PLUGIN_HANDLED;
}
public fw_PlayerSpawnPost(id) {
    if(g_GlowSelected[id] == -1) 
        return PLUGIN_HANDLED
        
    else if(g_GlowSelected[id])
        set_user_rendering(id, kRenderFxGlowShell, GlowLista[g_GlowSelected[id]][COLOR_R], GlowLista[g_GlowSelected[id]][COLOR_G], GlowLista[g_GlowSelected[id]][COLOR_B], kRenderNormal, GlowAmount)
        
    return PLUGIN_HANDLED;
} 


Si no les compila copiando el código por algún motivo, yo utilizo AMXMODX 1.8.1-300

Otra cosa, el código se ve re mal tabulado pero es el foro porque yo en mi amxmod-studio lo tengo tabulado normal ._.

[Valentina.]

GJ.

[meTaLiCroSS]

Versión tu vieja

Código PHP:

#include <amxmodx>
#include <hamsandwich>
#include <fun>

#define PLUGIN "Simple Glow Menu"
#define VERSION "1.0"
#define AUTHOR "tu vieja"

// Definimos el grosor del glow, mientras mas sea el numero, mas fuerte sera el glow
#define GlowAmount 20 

enum _:DATA_GLOW
{
    NOMBRE[32],
    COLOR_R,
    COLOR_G,
    COLOR_B
}

new const GlowLista[][DATA_GLOW] = 
{
    /* Nombre              - R    - G     - B */
    { "Blanco",         255, 255, 255},
    { "Verde",             0, 255, 10},
    { "Rojo",             255, 10, 0},
    { "Rosado",         200, 0, 200 },
    { "Verde Slime",     66, 245, 147 },
    { "Azul Mar",         66, 156, 245 },
    { "Purpura",         111, 66, 245 },
    { "Fuxia",             245, 66, 123 },
    { "Rojo Sangre",     245, 66, 66 },
    { "Arcilla",         79, 71, 61 },
    { "Verde Lima",     146, 255, 69 }
}

new g_GlowSelected[33];

public plugin_init() 
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_clcmd("say /glowmenu", "ClCmd_GlowMenu")
    RegisterHam(Ham_Spawn, "player", "OnPlayer_Spawn_Post", true)
}

public client_putinserver(id) 
{
    g_GlowSelected[id] = -1
}

public ClCmd_GlowMenu(id) 
{
    new menu = menu_create("Menu de Glow", "GlowMenuHandler")
    
    menu_additem(menu, "\yRemover Brillo^n")
    
    for(new i = 0; i < sizeof(GlowLista); i++) 
        menu_additem(menu, GlowLista[i][NOMBRE]);
    
    menu_display(id, menu, 0)
    return PLUGIN_HANDLED;
}

public GlowMenuHandler(id, menu, item) 
{
    if(item == MENU_EXIT)
    {
        menu_destroy(menu)
        return PLUGIN_HANDLED;
    }
    
    if(item == 0) 
    {
        if(g_GlowSelected[id] < 0) 
        {
            client_print_color(id, print_team_default, "^4[GLOW]^1 Tu no tienes un brillo seleccionado")
            
            menu_display(id, menu, 0)
            return PLUGIN_HANDLED
        }
        else
        {
            g_GlowSelected[id] = -1
            client_print_color(id, print_team_default, "^4[GLOW]^1 Tu brillo fue removido!")
            
            if(is_user_alive(id)) // no le vas a cambiar el glow estando muerto, gil
                ResetGlow(id)
        }
    } 
    else // se asume que los hay un item de slot 0 (primera opcion) y otro de rango [1 , sizeof(GlowLista)]
    {
        item -= 1 // se corrige el offset
        
        if(g_GlowSelected[id] == item)
        {
            client_print_color(id, print_team_default, "^4[GLOW]^1 Ya tienes este brillo")
            menu_display(id, menu, 0) // y mostrale el menu de nuevo, que pajero 
            return PLUGIN_HANDLED
        }
        else 
        {
            g_GlowSelected[id] = item
            
            if(is_user_alive(id)) 
            {
                ResetGlow(id)
                client_print_color(id, print_team_default, "^4[GLOW]^1 Has elegido el color ^4%s^1", GlowLista[item][NOMBRE])
            }
            else
            {
                client_print_color(id, print_team_default, "^4[GLOW]^1 En tu proximo Spawn tendras el color ^4%s^1", GlowLista[item][NOMBRE])
            }
        }
    }
    
    menu_destroy(menu) // para corregir lindo memory leak, te spameo este comando y te rompo el server si no tienes esto
    return PLUGIN_HANDLED;
}

public OnPlayer_Spawn_Post(id) 
{
    if(is_user_alive(id)) 
        ResetGlow(id)
} 

ResetGlow(id)
{
    (g_GlowSelected[id] > -1) ?
        set_user_rendering(id, 
                            kRenderFxGlowShell, 
                            GlowLista[g_GlowSelected[id]][COLOR_R], 
                            GlowLista[g_GlowSelected[id]][COLOR_G], 
                            GlowLista[g_GlowSelected[id]][COLOR_B], 
                            kRenderNormal, 
                            GlowAmount) :
        set_user_rendering(id) ;
} 


[Nazy.-]

Versión tu vieja

Código PHP:

#include <amxmodx>
#include <hamsandwich>
#include <fun>

#define PLUGIN "Simple Glow Menu"
#define VERSION "1.0"
#define AUTHOR "tu vieja"

// Definimos el grosor del glow, mientras mas sea el numero, mas fuerte sera el glow
#define GlowAmount 20 

enum _:DATA_GLOW
{
 NOMBRE[32],
 COLOR_R,
 COLOR_G,
 COLOR_B
}

new const GlowLista[][DATA_GLOW] = 
{
 /* Nombre  - R - G - B */
 { "Blanco", 255, 255, 255},
 { "Verde", 0, 255, 10},
 { "Rojo", 255, 10, 0},
 { "Rosado", 200, 0, 200 },
 { "Verde Slime", 66, 245, 147 },
 { "Azul Mar", 66, 156, 245 },
 { "Purpura", 111, 66, 245 },
 { "Fuxia", 245, 66, 123 },
 { "Rojo Sangre", 245, 66, 66 },
 { "Arcilla", 79, 71, 61 },
 { "Verde Lima", 146, 255, 69 }
}

new g_GlowSelected[33];

public plugin_init() 
{
 register_plugin(PLUGIN, VERSION, AUTHOR)
 
 register_clcmd("say /glowmenu", "ClCmd_GlowMenu")
 RegisterHam(Ham_Spawn, "player", "OnPlayer_Spawn_Post", true)
}

public client_putinserver(id) 
{
 g_GlowSelected[id] = -1
}

public ClCmd_GlowMenu(id) 
{
 new menu = menu_create("Menu de Glow", "GlowMenuHandler")
 
 menu_additem(menu, "\yRemover Brillo^n")
 
 for(new i = 0; i < sizeof(GlowLista); i++) 
 menu_additem(menu, GlowLista[i][NOMBRE]);
 
 menu_display(id, menu, 0)
 return PLUGIN_HANDLED;
}

public GlowMenuHandler(id, menu, item) 
{
 if(item == MENU_EXIT)
 {
 menu_destroy(menu)
 return PLUGIN_HANDLED;
 }
 
 if(item == 0) 
 {
 if(g_GlowSelected[id] < 0) 
 {
 client_print_color(id, print_team_default, "^4[GLOW]^1 Tu no tienes un brillo seleccionado")
 
 menu_display(id, menu, 0)
 return PLUGIN_HANDLED
 }
 else
 {
 g_GlowSelected[id] = -1
 client_print_color(id, print_team_default, "^4[GLOW]^1 Tu brillo fue removido!")
 
 if(is_user_alive(id)) // no le vas a cambiar el glow estando muerto, gil
 ResetGlow(id)
 }
 } 
 else // se asume que los hay un item de slot 0 (primera opcion) y otro de rango [1 , sizeof(GlowLista)]
 {
 item -= 1 // se corrige el offset
 
 if(g_GlowSelected[id] == item)
 {
 client_print_color(id, print_team_default, "^4[GLOW]^1 Ya tienes este brillo")
 menu_display(id, menu, 0) // y mostrale el menu de nuevo, que pajero 
 return PLUGIN_HANDLED
 }
 else 
 {
 g_GlowSelected[id] = item
 
 if(is_user_alive(id)) 
 {
 ResetGlow(id)
 client_print_color(id, print_team_default, "^4[GLOW]^1 Has elegido el color ^4%s^1", GlowLista[item][NOMBRE])
 }
 else
 {
 client_print_color(id, print_team_default, "^4[GLOW]^1 En tu proximo Spawn tendras el color ^4%s^1", GlowLista[item][NOMBRE])
 }
 }
 }
 
 menu_destroy(menu) // para corregir lindo memory leak, te spameo este comando y te rompo el server si no tienes esto
 return PLUGIN_HANDLED;
}

public OnPlayer_Spawn_Post(id) 
{
 if(is_user_alive(id)) 
 ResetGlow(id)
} 

ResetGlow(id)
{
 (g_GlowSelected[id] > -1) ?
 set_user_rendering(id, 
 kRenderFxGlowShell, 
 GlowLista[g_GlowSelected[id]][COLOR_R], 
 GlowLista[g_GlowSelected[id]][COLOR_G], 
 GlowLista[g_GlowSelected[id]][COLOR_B], 
 kRenderNormal, 
 GlowAmount) :
 set_user_rendering(id) ;
} 


mm... ¿Gracias? Supongo... Tu eres más avanzado que yo así que no puedes comparar...

[meTaLiCroSS]

mm... ¿Gracias? Supongo... Tu eres más avanzado que yo así que no puedes comparar...

Quien está comparando

[alexiways]

Ya esta creado, si colocas un sistema de guardado de brillo te aplaudo

[Nazy.-]

Ya esta creado, si colocas un sistema de guardado de brillo te aplaudo

easy x adv vault

[alexiways]

hacelo :V