11/10/2017, 03:40 PM
Buenas tengo una duda de como arreglo el codigo que esta posteado aca por que al momento de registrarme no sucede nada coloco la contraseña y me sale error y no continua le adjunto el sma para que puedan ayudarme
Código PHP:
/* -----------------------------------------
Creditos: Solo para Raulitop, por el hook say :3
Version Con Guardado NFVAULT
------------------------------- */
#include <amxmisc>
#include <hamsandwich>
#include <cstrike>
#include <fun>
#include <fakemeta>
#include <adv_vault>
new const PLUGIN[] = "Rangos CS:GO"
#define VERSION "1.0"
new const AUTHOR[] = "kikizon"
/* =============================================
|= [EMPIEZA SECCION MODIFICABLE] =|
==============================================*/
/* ====================================
*[CONSTANTES]*
=====================================*/
new const Web[] = "AMXMODX-ES.COM" // Se Muestra en HUD
new const Prefijo[] = "!g[RANGOS]!y" // Prefijo en say
new const Sonido[] = "rango/up.wav" // Sonido Rango UP
/* ====================================
*[CONST NOMBRES DE RANGOS]*
=====================================*/
enum _:DATA
{
NOMBRE[ 90 ],
FRAGS,
WEAPON_NAME[ 90 ],
WEAPON_MODEL[ 90 ],
WEAPON_CSW,
WEAPON_AMMO
};
new const Rangos[][DATA] =
{
{ "Sin Rango", 100, "weapon_tmp", "default", CSW_GLOCK18, 99 },
{ "Silver I", 200, "weapon_mac10", "default", CSW_MAC10, 99 },
{ "Silver II", 300, "weapon_ump45", "default", CSW_UMP45, 99 },
{ "Silver III", 500, "weapon_mp5navy", "default", CSW_MP5NAVY, 99 },
{ "Silver IV", 700, "weapon_p90", "default", CSW_P90, 99 },
{ "Silver Elite", 800, "weapon_m3", "default", CSW_M3, 99 },
{ "Silver Elite Master", 900, "weapon_xm1014", "default", CSW_XM1014, 99 },
{ "Gold Nova I", 1000, "weapon_famas", "default", CSW_FAMAS, 99 },
{ "Gold Nova II", 1200, "weapon_galil", "v_galil", CSW_GALIL, 99 },
{ "Gold Nova III", 1300, "weapon_aug", "default", CSW_AUG, 99 },
{ "Gold Nova Master", 1400, "weapon_ak47", "default", CSW_AK47, 99 },
{ "Master Guardian I",1500, "weapon_m4a1", "default", CSW_M4A1, 99 },
{ "Master Guardian II", 1700, "weapon_sg552", "default", CSW_SG552, 99 },
{ "Master Guardian Elite", 1800, "weapon_g3sg1", "default", CSW_G3SG1 },
{ "Distinguished Master Guardian", 1900, "weapon_sg550", "default", CSW_SG550, 99 },
{ "Legendary Eagle", 2000, "weapon_m249", "default", CSW_M249, 99 },
{ "Legendary Eagle Master", 2100, "weapon_glock18", "default", CSW_GLOCK18, 99 },
{ "Supreme Master First Class", 2200, "weapon_usp", "default", CSW_USP, 99 },
{ "The Global Elite", 999999, "weapon_deagle", "default", CSW_DEAGLE, 99 },
{ "Supreme Master BUG", 99999, "weapon_p228", "default", CSW_P228, 99 }
};
/* =============================================
|= [TERMINA SECCION MODIFICABLE] =|
==============================================*/
/* ====================================
*[VARIABLES]*
=====================================*/
new g_rango[33], g_frags[33], g_primary[33];
new SyncHUD, g_maxplayers, g_msgTeamInfo, g_msgSayText;
#define TASK_HUD 2100
#define ID_HUD (taskid - TASK_HUD)
new const P_INFO[ ][ ] = { "Sistema de Cuentas [ Advanced Vault ]", "1.3b", "kikizon" };
new const szStatus[ ][ ] = { "No Registrado", "Registrado", "Logueado"};
#define PW_LENGHT 32
enum { NOT_REGISTERED, REGISTERED, LOGUED, MAX_STATUS }
enum _:MAX_VARS { VAULT, VAULT2, FIELDFRAG, FIELDRANGE, FIELDPW, FIELDDATE, FIELD2, TOTALACCOUNTS }
enum _:MAX_MSG { MSG_SHOWMENU, MSG_VGUIMENU }
enum { LOAD = 0, SAVE }
new kStatus[ 33 ], kPN[ 33 ][ 32 ], kPassword[ 33 ][ PW_LENGHT ], kPwCache[ 33 ][ PW_LENGHT ], kDate[ 33 ][ 35 ], bool:kCanChange[ 33 ];
new kVars[ MAX_VARS ], kMsg[ MAX_MSG ];
/* ====================================
*[Cvars]*
=====================================*/
new cvar_Hud, cvar_knifex2, cvar_hsx2
/* ====================================
*[INIT]*
=====================================*/
public plugin_init() {
register_plugin(PLUGIN, VERSION, AUTHOR)
register_event("DeathMsg", "Event_DeathMsg", "a")
register_logevent("logevent_round_end", 2, "1=Round_End")
register_clcmd("say", "message_saytext")
register_clcmd("say_team", "message_sayteam")
/* =============================================
|= [EMPIEZA SECCION MODIFICABLE] =|
==============================================*/
register_clcmd( "JOIN_PASSWORD", "JoinPassword" );
register_clcmd( "say /cuenta", "ShowLoginMenu" );
cvar_Hud = register_cvar("rangos_hud", "1") // 1 - Mostrar HUD | 0 - No Mostrar
cvar_knifex2 = register_cvar("rangos_knifex2", "1") // 1 - x2 frags con knife | 0 - NO :v
cvar_hsx2 = register_cvar("rangos_hsx2", "1") // 1 - x2 frags de HeadShot | 0 - NO :v
/* =============================================
|= [TERMINA SECCION MODIFICABLE] =|
==============================================*/
kMsg[ MSG_SHOWMENU ] = get_user_msgid( "ShowMenu" );
kMsg[ MSG_VGUIMENU ] = get_user_msgid( "VGUIMenu" );
register_message(kMsg[MSG_VGUIMENU], "message_VGUImenu");
register_message(kMsg[MSG_SHOWMENU], "message_VGUImenu");
RegisterHam(Ham_Spawn, "player", "fw_PlayerSpawn_Post", 1);
for( new i = 0; i < sizeof Rangos; i++ )
RegisterHam(Ham_Item_Deploy, Rangos[i][WEAPON_NAME], "fHam_WeaponDeployPost", 1)
SyncHUD = CreateHudSyncObj()
g_maxplayers = get_maxplayers()
g_msgTeamInfo = get_user_msgid("TeamInfo")
g_msgSayText = get_user_msgid("SayText")
kVars[ VAULT ] = adv_vault_open( "CLIENT_DATA", false );
kVars[ FIELDFRAG ] = adv_vault_register_field( kVars[ VAULT ], "Frags" );
kVars[ FIELDRANGE ] = adv_vault_register_field( kVars[ VAULT ], "Rangos" );
kVars[ FIELDPW ] = adv_vault_register_field( kVars[ VAULT ], "Password", DATATYPE_STRING, PW_LENGHT-1 );
kVars[ FIELDDATE ] = adv_vault_register_field( kVars[ VAULT ], "Date", DATATYPE_STRING, charsmax(kDate[]));
adv_vault_init( kVars[ VAULT ] );
kVars[ VAULT2 ] = adv_vault_open("TOTALACCOUNTS", false);
kVars[ FIELD2 ] = adv_vault_register_field( kVars[ VAULT2 ], "CuentasCreadas", DATATYPE_INT );
adv_vault_init( kVars[ VAULT2 ] );
LoadTotalAccounts();
}
/* ====================================
*[PRECACHE]*
=====================================*/
public plugin_precache()
{
new i;
precache_sound(Sonido)
static szBuffer[64];
for( i = 0; i < sizeof( Rangos ); i++ )
{
if( !equal( Rangos[ i ][ WEAPON_MODEL ], "default" ) )
{
formatex(szBuffer, charsmax(szBuffer), "models/Armas/%s.mdl", Rangos[ i ][ WEAPON_MODEL ] );
precache_model(szBuffer);
}
}
}
/* ===================================
*[HUD]*
=====================================*/
public HUD(taskid) {
new id = ID_HUD
if (!is_user_alive(id)) {
id = pev(id, pev_iuser2)
if (!is_user_alive(id)) return;
}
if(id != ID_HUD) {
set_hudmessage(255, 255, 255, 0.60, 0.67, 1, 6.0, 1.0)
ShowSyncHudMsg(ID_HUD, SyncHUD, "Frags: %d || Rango: %s", g_frags[id], Rangos[g_rango[id]][NOMBRE])
} else {
set_hudmessage(0, 255, 0, 0.0, 0.20, 1, 6.0, 1.0)
ShowSyncHudMsg(ID_HUD, SyncHUD, "=======================^nFrags: %d^nRango: %s^n=======================^nSig. Rango: %s^nFrags Restantes: %d^n=======================^n%s",
g_frags[id], Rangos[g_rango[id]][NOMBRE], Rangos[g_rango[id]+1][NOMBRE], Rangos[g_rango[id]][FRAGS] - g_frags[id], Web)
}
}
/* ==================================
[PUTINSERVER]
===================================*/
public client_putinserver(id) {
get_user_name( id, kPN[ id ], 31 );
get_time("%c", kDate[ id ], charsmax( kDate[ ] ) );
kCanChange[ id ] = false;
g_rango[id] = 0
g_frags[id] = 0
Manage_Data( id, LOAD );
if(get_pcvar_num(cvar_Hud))
set_task(1.0, "HUD", id+TASK_HUD, _, _, "b")
}
public message_VGUImenu(msgid, dest, index)
{
if(kStatus[index] != LOGUED)
ShowLoginMenu(index);
return 1;
}
public fw_PlayerSpawn_Post( index )
{
if (!is_user_connected( index ) || cs_get_user_team( index ) == CS_TEAM_UNASSIGNED || cs_get_user_team( index ) == CS_TEAM_SPECTATOR)
return;
strip_user_weapons( index );
give_item( index, "weapon_knife" );
check_weapons( index );
}
/* ==================================
[DISCONNECT]
===================================*/
public client_disconnect(id) {
Manage_Data( id, SAVE );
remove_task(id+TASK_HUD)
}
/* ==================================
[ROUND END]
===================================*/
public logevent_round_end() {
for(new id = 1; id <= g_maxplayers; id++)
Manage_Data( id, SAVE );
}
/* ==================================
[DEATHMSG]
===================================*/
public Event_DeathMsg() {
new attacker = read_data(1)
new victim = read_data(2)
new hs = read_data(3)
new weaponid = get_user_weapon(attacker)
if(victim == attacker) return;
if(is_user_alive(attacker)) {
g_frags[attacker]++
if(get_pcvar_num(cvar_knifex2)) {
if(weaponid == CSW_KNIFE)
g_frags[attacker]++
}
if(get_pcvar_num(cvar_hsx2)) {
if(hs) g_frags[attacker]++
}
AumentarRango(attacker)
}
}
/* ================================
[UPDATE RANGO]
=================================*/
AumentarRango(id) {
new Aumento = false
while(g_frags[id] >= Rangos[g_rango[id]][FRAGS]) {
Aumento = true
g_primary[id]++;
g_rango[id]++
}
if(Aumento) {
chatcolor(id, "%s Felicidades subiste al rango: !g[ %s ]", Prefijo, Rangos[g_rango[id]][NOMBRE])
client_cmd(id, "spk %s", Sonido)
Aumento = false
}
}
/*=====================================
*[SAY]*
=====================================*/
public message_saytext(id) {
static said[192]
read_args(said, charsmax(said))
remove_quotes(said)
if (said[0] == '@' || said[0] == '%' || said[0] == '/' || said[0] == '.' || said[0] == '!' || equal (said, ""))
return PLUGIN_HANDLED
if (!ValidMessage(said, 1)) return PLUGIN_CONTINUE;
static color[11], name[32], alive[11]
get_user_team(id,color,charsmax(color))
get_user_name(id,name,charsmax(name))
if (is_user_alive (id)) {
alive = ""
} else {
alive = "[Muerto]"
}
if (is_user_admin(id)) {
if (get_user_flags(id) & ADMIN_KICK)
format(said, charsmax(said), "^x01%s^x04%s ^x03%s ^x04: %s", alive, Rangos[g_rango[id]][NOMBRE], name, said)
} else {
format(said, charsmax(said), "^x01%s^04%s ^x03%s ^x01: %s", alive, Rangos[g_rango[id]][NOMBRE], name, said)
}
static i, team[11]
for (i = 1; i <= g_maxplayers; i++) {
if (!is_user_connected(i)) continue
get_user_name(id,name,charsmax(name))
if (is_user_admin(i) || is_user_alive(id) && is_user_alive(i) || !is_user_alive(id) && !is_user_alive(i)) {
get_user_team(i, team, charsmax(team))
changeTeamInfo(i, color)
writeMessage(i, said)
changeTeamInfo(i, team)
}
}
return PLUGIN_HANDLED_MAIN;
}
public message_sayteam(id)
{
static said[192]
read_args(said, charsmax(said))
remove_quotes(said)
if (said[0] == '@' || said[0] == '%' || said[0] == '/' || said[0] == '.' || said[0] == '!' || equal (said, ""))
return PLUGIN_HANDLED
if (!ValidMessage(said, 1)) return PLUGIN_CONTINUE;
static playerTeam, playerTeamName[19]
playerTeam = get_user_team(id)
switch (playerTeam) {
case 1: copy (playerTeamName, 6, "TE")
case 2: copy (playerTeamName, 8, "CT")
default: copy (playerTeamName, 11, "SPEC")
}
static color[11], name[32], alive[11]
get_user_team(id,color,charsmax(color))
get_user_name(id,name,charsmax(name))
if (is_user_alive (id)) {
alive = ""
} else {
alive = "[MUERTO]"
}
if (is_user_admin(id)) {
if (get_user_flags(id) & ADMIN_RCON)
format(said, charsmax(said), "^x01%s [ %s ] ^x04%s ^x03%s ^x04: %s", alive, playerTeam, Rangos[g_rango[id]], name, said)
} else {
format(said, charsmax(said), "^x01%s [ %s ] ^04%s ^x03%s ^x01: %s", alive, playerTeam, Rangos[g_rango[id]],name, said)
}
static i, team[11]
for (i = 1; i <= g_maxplayers; i++) {
if (!is_user_connected(i)) continue;
get_user_name(id,name,charsmax(name))
if (get_user_team(i) == playerTeam || is_user_admin(i)) {
if (is_user_alive(id) && is_user_alive(i) || !is_user_alive(id) && !is_user_alive(i)) {
get_user_team(i, team, charsmax(team))
changeTeamInfo(i, color)
writeMessage(i, said)
changeTeamInfo(i, team)
}
}
}
return PLUGIN_HANDLED_MAIN;
}
public changeTeamInfo(player, team[]) {
message_begin(MSG_ONE, g_msgTeamInfo, _, player)
write_byte(player)
write_string(team)
message_end()
}
public writeMessage(player, message[]) {
message_begin(MSG_ONE, g_msgSayText, {0, 0, 0}, player)
write_byte(player)
write_string(message)
message_end()
}
/* ===================================
*[GUARDADO]*
=====================================*/
public JoinPassword( index )
{
read_args( kPassword[ index ], PW_LENGHT-1 );
remove_quotes( kPassword[ index ] );
trim( kPassword[ index ] );
if(equal(kPassword[index], "") || containi(kPassword[index]," ") != -1)
{
client_print(index, print_center, "Tu password contiene errores");
return;
}
switch( kStatus[ index ] )
{
case NOT_REGISTERED:
{
client_print(index, print_center, "Confirma tu password");
copy( kPwCache[index], PW_LENGHT-1, kPassword[index]);
ShowConfirmationMenu( index );
}
case REGISTERED:
{
new buffer[ PW_LENGHT ];
adv_vault_get_prepare( kVars[ VAULT ], _, kPN[ index ] );
adv_vault_get_field( kVars[ VAULT ], kVars[ FIELDPW ], buffer, PW_LENGHT-1 );
if( equal( buffer, kPassword[ index ]) )
{
Manage_Data(index, SAVE);
client_print(index, print_center, "Te has logueado");
ForceJoinTeam( index );
return;
}
ShowLoginMenu( index );
client_print(index, print_center, "Password Incorrecta.");
}
case LOGUED:
{
if( kCanChange[ index ] )
{
client_print(index, print_center, "No Permitido...");
return;
}
client_print( index, print_center, "Confirma tu password para cambiarla..." );
copy( kPwCache[ index ], PW_LENGHT-1, kPassword[ index ]);
ShowConfirmationMenu( index );
}
}
}
/* ===========================================================================??=================== */
public ShowLoginMenu(index)
{
static tittle[999], len; len = 0;
len += formatex(tittle[len], charsmax(tittle) - len, "\rAccount system by \d%s \y^n", P_INFO[ 2 ] );
len += formatex(tittle[len], charsmax(tittle) - len, "\yNumero total de cuentas: \d%d^n^n", kVars[ TOTALACCOUNTS ]);
len += formatex(tittle[len], charsmax(tittle) - len, "\wBienvenido: \d%s^n", kPN[ index ] );
len += formatex(tittle[len], charsmax(tittle) - len, "\wEstado: \d[ \r%s \d]^n", szStatus[ kStatus[ index ] ] );
len += formatex(tittle[len], charsmax(tittle) - len, "\wTu ultima Visita Fue: \d%s^n^n", !kDate[index][0] ? "NUNCA": kDate[ index ]);
new menu = menu_create(tittle,"menu_login");
menu_additem(menu, (kStatus[index] == REGISTERED)?"Loguearse":"\dLoguearse", "1");
menu_additem(menu, (kStatus[index] == NOT_REGISTERED)?"Registrarse^n":"\dRegistrarse^n", "2");
menu_additem(menu, (kStatus[index] == LOGUED && !kCanChange[ index ])?"Cambiar pass":"\dCambiar pass", "3");
menu_setprop(menu, MPROP_EXIT, MEXIT_NEVER);
menu_display(index, menu );
return PLUGIN_HANDLED;
}
ShowConfirmationMenu(index)
{
static tittle[ 128 ];
formatex(tittle, 127, "La password sera \r%s^n^n\yContinuar?", kPwCache[ index ]);
new menu = menu_create(tittle,"menu_confirm");
menu_additem(menu,"\rSi\w, adelante","1");
menu_additem(menu,"\rNo\w, deseo reescribirla","2");
menu_setprop(menu, MPROP_EXIT, MEXIT_NEVER);
menu_display(index, menu, 0);
}
public menu_login(index, menu, item)
{
switch(item)
{
case 0:
{
if(kStatus[index] == REGISTERED)
{
client_print(index, print_center, "Ingresa tu PASSWORD para entrar a tu cuenta");
client_cmd(index,"messagemode ^"JOIN_PASSWORD^"");
return PLUGIN_HANDLED;
}
client_print(index, print_center, "No puedes elegir esta opcion");
}
case 1:
{
if(kStatus[index] == NOT_REGISTERED)
{
client_print(index, print_center, "Ingresa una PASSWORD para crear una cuenta");
client_cmd(index,"messagemode ^"JOIN_PASSWORD^"");
return PLUGIN_HANDLED;
}
client_print(index, print_center, "No puedes elegir esta opcion");
}
case 2:
{
if(kStatus[index] == LOGUED && !kCanChange[ index ])
{
client_print(index, print_center, "Ingresa tu nueva PASSWORD");
client_cmd(index,"messagemode ^"JOIN_PASSWORD^"");
return PLUGIN_HANDLED;
}
client_print(index, print_center, "No estas logueado o ya cambiaste tu password");
}
case MENU_EXIT: { menu_destroy(menu); return PLUGIN_HANDLED; }
}
menu_destroy(menu);
return PLUGIN_HANDLED;
}
public menu_confirm(index, menu, item)
{
switch(item)
{
case 0:
{
switch(kStatus[index])
{
case LOGUED:
{
copy(kPassword[index], PW_LENGHT-1, kPwCache[index]);
Manage_Data(index, SAVE);
client_print(index, print_center, "Tu password ha sido cambiada satisfactoriamente");
kCanChange[ index ] = true;
}
case NOT_REGISTERED:
{
kVars[ TOTALACCOUNTS ]++;
client_print(index, print_center, "Tu cuenta ha sido creada satisfactoriamente");
copy(kPassword[index], PW_LENGHT-1, kPwCache[index]);
Manage_Data(index, 1);
ForceJoinTeam(index);
adv_vault_set_start( kVars[ VAULT2 ] );
adv_vault_set_field( kVars[ VAULT2 ], kVars[ FIELD2 ], kVars[ TOTALACCOUNTS ] );
adv_vault_set_end( kVars[ VAULT2 ], 1 );
}
}
}
case 1:
{
menu_destroy(menu);
client_cmd(index,"messagemode JOIN_PASSWORD");
if(kStatus[index] == LOGUED)
client_print(index, print_center, "Ingresa tu nueva PASSWORD");
else
client_print(index, print_center, "Ingresa la PASSWORD para tu nueva cuenta");
}
case MENU_EXIT: { menu_destroy(menu); return PLUGIN_HANDLED; }
}
menu_destroy(menu);
return PLUGIN_HANDLED;
}
/* ===========================================================================??=================== */
ForceJoinTeam(index)
{
static teammsg_block, teammsg_block_vgui, restore, vgui;
restore = get_pdata_int(index, 510);
vgui = restore & (1<<0);
if (vgui) set_pdata_int(index, 510, restore & ~(1<<0));
teammsg_block = get_msg_block(kMsg[MSG_SHOWMENU]);
teammsg_block_vgui = get_msg_block(kMsg[MSG_VGUIMENU]);
set_msg_block(kMsg[MSG_SHOWMENU], BLOCK_ONCE);
set_msg_block(kMsg[MSG_VGUIMENU], BLOCK_ONCE);
engclient_cmd(index, "jointeam", "5");
engclient_cmd(index, "joinclass", "5");
set_msg_block(kMsg[MSG_SHOWMENU], teammsg_block);
set_msg_block(kMsg[MSG_VGUIMENU], teammsg_block_vgui);
if (vgui) set_pdata_int(index, 510, restore);
kStatus[index] = LOGUED;
}
LoadTotalAccounts()
{
if ( !adv_vault_get_prepare( kVars[ VAULT2 ], 1) )
{
adv_vault_set_start( kVars[ VAULT2 ]);
kVars[ TOTALACCOUNTS ] = 0;
adv_vault_set_field( kVars[ VAULT2 ], kVars[ FIELD2 ], kVars[ TOTALACCOUNTS ]);
adv_vault_set_end( kVars[ VAULT2 ], 1);
return;
}
kVars[ TOTALACCOUNTS ] = adv_vault_get_field( kVars[ VAULT2 ], kVars[ FIELD2 ]);
}
Manage_Data( index, type )
{
if( !is_user_connected( index ) ) return;
if( type == LOAD )
{
if( !adv_vault_get_prepare( kVars[ VAULT ], _, kPN[ index ] ) )
{
kStatus[index] = NOT_REGISTERED;
return;
}
kStatus[ index ] = REGISTERED;
g_frags[ index ] = adv_vault_get_field( kVars[ VAULT ], kVars[ FIELDFRAG ] );
g_rango[ index ] = adv_vault_get_field( kVars[ VAULT ], kVars[ FIELDRANGE ] );
adv_vault_get_field( kVars[ VAULT ], kVars[ FIELDPW ], kPassword[index], PW_LENGHT-1 );
adv_vault_get_field( kVars[ VAULT ], kVars[ FIELDDATE ], kDate[ index ], charsmax(kDate[]) );
}
if( type == SAVE )
{
adv_vault_set_start( kVars[ VAULT ] );
adv_vault_set_field( kVars[ VAULT ], kVars[ FIELDFRAG ], g_frags[ index ] );
adv_vault_set_field( kVars[ VAULT ], kVars[ FIELDRANGE ], g_rango[ index ] );
adv_vault_set_field( kVars[ VAULT ], kVars[ FIELDPW ], kPassword[ index ] );
adv_vault_set_field( kVars[ VAULT ], kVars[ FIELDDATE ], kDate[ index ] );
adv_vault_set_end( kVars[ VAULT ], 0, kPN[ index ] );
}
}
/* ===================================
*[STOCKS]*
=====================================*/
// stock de chatcolor
stock chatcolor(id, const input[], any:...) {
new count = 1, players[32];
static msg[191];
vformat(msg, 190, input, 3);
replace_all(msg, 190, "!g", "^4"); // Verde
replace_all(msg, 190, "!y", "^1"); // Default
replace_all(msg, 190, "!t", "^3"); // Color del Equipo
if (id) players[0] = id; else get_players(players, count, "ch"); {
for (new i = 0; i < count; i++) {
if (is_user_connected(players[i])) {
message_begin(MSG_ONE_UNRELIABLE, get_user_msgid("SayText"), _, players[i]);
write_byte(players[i]);
write_string(msg);
message_end();
}
}
}
}
// Stock para Saber Si el mensaje es valido
stock ValidMessage(text[], maxcount) {
static len, i, count
len = strlen(text)
count = 0
if (!len)
return false;
for (i = 0; i < len; i++) {
if (text[i] != ' ') {
count++
if (count >= maxcount)
return true;
}
}
return false;
}
public check_weapons( index )
{
if( !is_user_alive( index ) )
return;
g_primary[ index ] = g_rango[ index ];
give_item( index, Rangos[ g_primary[ index ] ][ WEAPON_NAME ] );
cs_set_user_bpammo( index, get_weaponid( Rangos[ g_primary[ index ] ][ WEAPON_NAME ] ), Rangos[ g_primary[ index ] ][ WEAPON_AMMO ] );
}
public fHam_WeaponDeployPost( Weapon )
{
static iOwner; iOwner = get_weapon_ent_owner( Weapon );
if( !pev_valid( iOwner ) || !is_user_alive( iOwner ) ) return;
static iWeaponInf, WeaponPrim;
iWeaponInf = cs_get_weapon_id( Weapon );
WeaponPrim = Rangos[ g_primary[ iOwner ] ][ WEAPON_CSW ];
static szBuffer[64];
if( iWeaponInf == WeaponPrim )
{
if( !equal( Rangos[ g_primary[ iOwner ] ][ WEAPON_MODEL ], "default" ) )
{
formatex(szBuffer, charsmax(szBuffer), "models/Armas/%s.mdl", Rangos[ g_primary[ iOwner ] ][ WEAPON_MODEL ] );
set_pev(iOwner, pev_viewmodel2, szBuffer);
}
}
}
stock get_weapon_ent_owner( ent )
{
if ( ~pev_valid( ent ) & 2 ) return -1;
return get_pdata_cbase( ent, 41, 4 );
}
