Remove Entity (Camara)

[MatiasGFaria]

hola me sale este error en el plugin de la camara:

L 09/22/2022 - 17:39:37: [AMXX] Displaying debug trace (plugin "Camara_new.amxx", version "0.0.1")
L 09/22/2022 - 17:39:37: [AMXX] Run time error 10: native error (native "remove_entity")
L 09/22/2022 - 17:39:37: [AMXX] [0] Camara_new.sma::client_disconnected (line 58)

Código PHP:

#include <amxmodx>
#include <engine>
#include <fakemeta>
#include <fun>
#include <hamsandwich>

#define VERSION "0.0.1"

#define MAX_PLAYERS    32

#define    m_flWait        42

#define USE_TOGGLE 3

new g_iCam[MAX_PLAYERS+1]
new g_iMaxPlayers

public plugin_init()
{
    register_plugin("Camera View", VERSION, "ConnorMcLeod")

    register_clcmd("say /cam", "cam")
    register_think("trigger_camera", "Camera_Think")
    g_iMaxPlayers = get_maxplayers()
}

public cam( id )
{
    if( !is_user_alive(id) )
    {
        return
    }
    new iEnt = g_iCam[id]
    if( !is_valid_ent(iEnt) )
    {
        iEnt = create_entity("trigger_camera")

        entity_set_int(iEnt, EV_INT_spawnflags, SF_CAMERA_PLAYER_TARGET|SF_CAMERA_PLAYER_POSITION)

        DispatchSpawn(iEnt)
        set_pdata_float(iEnt, m_flWait, 999999.0, 4)

        g_iCam[id] = iEnt
    }

    ExecuteHam( Ham_Use, iEnt, id, id, USE_TOGGLE, 1.0)

    entity_set_int(id, EV_INT_flags, entity_get_int(id, EV_INT_flags) & ~FL_FROZEN)
    cs_reset_user_maxspeed(id)
}

public client_disconnected(id)
{
    new iEnt = g_iCam[id]
    if( !is_valid_ent(iEnt) )
    {
        g_iCam[id] = 0
        remove_entity(iEnt)
    }
}

cs_reset_user_maxspeed(id)
{
    new Float:flMaxSpeed;
    switch ( get_user_weapon(id) )
    {
        case CSW_SG550, CSW_AWP, CSW_G3SG1 : flMaxSpeed = 210.0;
        case CSW_M249 : flMaxSpeed = 220.0;
        case CSW_AK47 : flMaxSpeed = 221.0;
        case CSW_M3, CSW_M4A1 : flMaxSpeed = 230.0;
        case CSW_SG552 : flMaxSpeed = 235.0;
        case CSW_XM1014, CSW_AUG, CSW_GALIL, CSW_FAMAS : flMaxSpeed = 240.0;
        case CSW_P90 : flMaxSpeed = 245.0;
        case CSW_SCOUT : flMaxSpeed = 260.0;
        default : flMaxSpeed = 250.0;
    }
    set_user_maxspeed(id, flMaxSpeed);
}

get_cam_owner(iEnt)
{
    static id
    for(id = 1; id<=g_iMaxPlayers; id++)
    {
        if( g_iCam[id] == iEnt )
        {
            return id
        }
    }
    return 0
}

public Camera_Think(entid)
{
    new id = get_cam_owner(entid);
    if( !id )
    {
        return
    }

    static Float:origin[3], Float:angle[3], Float:vBack[3];
    entity_get_vector( id, EV_VEC_origin, origin );
    entity_get_vector( id, EV_VEC_v_angle, angle );

    angle_vector( angle, ANGLEVECTOR_FORWARD, vBack );

    origin[2] += 20.0; //So we're closer to the eyes.

    //Move back to see ourself (150 units)
    origin[0] += (-vBack[0] * 150.0);
    origin[1] += (-vBack[1] * 150.0);
    origin[2] += (-vBack[2] * 150.0);

    entity_set_origin( entid, origin );
    entity_set_vector( entid, EV_VEC_angles, angle );  

    entity_set_float(entid, EV_FL_nextthink, get_gametime())
} 


[Hinami]

prueba removiendo ! del if

[XSlayer]

Código:

public client_disconnected(id)
{
    new iEnt = g_iCam[id]
    if( !is_valid_ent(iEnt) )
    {
        g_iCam[id] = 0
        remove_entity(iEnt)
    }
}

==>

Código:

public client_disconnected(id)
{
    if(is_valid_ent(g_iCam[id]))
    {
        remove_entity( g_iCam[id] );
        g_iCam[id] = 0;
    }
}

Para que entiendas tus errores:

1 - Estas creando la variable iEnt innecesariamente cuando podrias llamar a g_iCam[id] directamente
2 - La condicion que estas usando es equivocada, estas preguntando si la entidad no es valida, si no es valida obviamente te lanzara un error al remover una entidad que no existe..

Hay muchas correciones que hacerle al codigo, mañana te lo envio reparado, actualmente son las 3:40 en mi pais, Saludos!

[XSlayer]

Código PHP:

#include <amxmodx>
#include <engine>
#include <fakemeta>
#include <fun>
#include <hamsandwich>
#include <xs>

new __int_Cam[33] = 0;
 
public plugin_init()
{
    register_plugin( "Camera_Mode", "1.0", "XSlayer" ); 
    register_think( "Camera_Think", "PCameraThink" );
    register_clcmd( "say /cam", "Change_Mode" );
}
public client_disconnected(Client)
{
    if(__int_Cam[Client])
    {
         remove_entity( __int_Cam[Client] );
         __int_Cam[Client] = 0;
    }
}
public Change_Mode( Client )
{
    if(!is_user_alive(Client)) { return 0; }
 
    if(!__int_Cam[Client])
    {
        __int_Cam[Client] = create_entity( "info_target" );
 
        entity_set_string( __int_Cam[Client], EV_SZ_classname, "Camera_Think" );
        entity_set_float( __int_Cam[Client], EV_FL_nextthink, get_gametime() + 0.1 );
   
        entity_set_int( __int_Cam[Client], EV_INT_spawnflags, SF_CAMERA_PLAYER_TARGET|SF_CAMERA_PLAYER_POSITION );
        entity_set_int( __int_Cam[Client], EV_INT_iuser1, Client );

        DispatchSpawn(__int_Cam[Client]);

        set_pdata_float( __int_Cam[Client], 42, 999999.0, 4 );

    }
    ExecuteHam( Ham_Use, __int_Cam[Client], Client, Client, 3, 1.0 );

    entity_set_int(Client, EV_INT_flags, entity_get_int(Client, EV_INT_flags) & ~FL_FROZEN)
    cs_reset_user_maxspeed(Client)

    return 1;
}
public PCamera_Think( __int_Entity )
{
    if(is_valid_ent(__int_Entity))
    {
        static __int_Owner;
        __int_Owner = entity_get_int( Client, EV_INT_iuser1 );

        static Float:__fl_v_Angles[3], Float:__fl_Origin[3], Float:__fl_End[3];
        static Float:__fl_v_AnglesF[3];

        entity_get_vector( Client, EV_VEC_v_angle, __fl_v_AnglesF );
        entity_get_vector( Client, EV_VEC_origin, __fl_Origin );

        __fl_Origin[2] += 20.0;

        angle_vector(__fl_v_AnglesF, ANGLEVECTOR_FORWARD, __fl_v_Angles);
        xs_vec_mul_scalar(__fl_v_Angles, -150.0, __fl_v_Angles);
        xs_vec_add(__fl_Origin, __fl_v_Angles, __fl_End); 

        entity_set_origin( __int_Entity, __fl_End );
        entity_set_vector( __int_Entity, EV_VEC_angles, __fl_v_AnglesF );
        entity_set_float( __int_Entity, EV_FL_nextthink, get_gametime() + 0.1 );  
    }
}
stock cs_reset_user_maxspeed(Client)
{
    new Float:flMaxSpeed;
    switch ( get_user_weapon(Client) )
    {
        case CSW_SG550, CSW_AWP, CSW_G3SG1 : flMaxSpeed = 210.0;
        case CSW_M249 : flMaxSpeed = 220.0;
        case CSW_AK47 : flMaxSpeed = 221.0;
        case CSW_M3, CSW_M4A1 : flMaxSpeed = 230.0;
        case CSW_SG552 : flMaxSpeed = 235.0;
        case CSW_XM1014, CSW_AUG, CSW_GALIL, CSW_FAMAS : flMaxSpeed = 240.0;
        case CSW_P90 : flMaxSpeed = 245.0;
        case CSW_SCOUT : flMaxSpeed = 260.0;
        default : flMaxSpeed = 250.0;
    }
    set_user_maxspeed(Client, flMaxSpeed);
} 


Aca esta!