: Soporte para models T

[Rider430]

Hola a todos!

Sera que me puedan ayudar a modificar este codigo para que pueda detectar models T, Gracias de antemano!

Código PHP:

#include <amxmodx>
#include <fakemeta>

/* ==========================================================
*                 [ Global stuff ]
* =========================================================== */

#define SetPlayerBit(%1,%2) ( %1 |= ( 1 << ( %2 & 31 ) ) )
#define GetPlayerBit(%1,%2) ( %1 & ( 1 << ( %2 & 31 ) ) )
#define ClearPlayerBit(%1,%2) ( %1 &= ~( 1 << ( %2 & 31 ) ) )

const ARG_MODELNAME = 1;
const ARG_PLAYERID = 12;

new const g_szCache_KeyModel[ ] = "model";
new const g_szModel[ ][ ] = { "admin_t","admin_ct","admin_girl_t","admin_girl_ct" };

new g_iAdmin,g_iGirl,g_szPlayerModel[ 33 ][ 32 ];

/* ==========================================================
*                 [ Initiation ]
* =========================================================== */

public plugin_precache( )
{
    new szData[ 64 ];
    
    for( new i;i < sizeof( g_szModel );i++ )
    {
        formatex( szData,charsmax( szData ),"models/player/%s/%s.mdl",g_szModel[ i ],g_szModel[ i ] );
        precache_model( szData );
    }
}

public plugin_init( )
{
    register_plugin( "Admin Models","1.0","Manu" );

    register_event( "TeamInfo","ev_TeamInfo","a" );
    register_forward( FM_SetClientKeyValue,"fw_ClientKeyValue" );
    register_message( get_user_msgid( "ClCorpse" ),"message_ClCorpse" );
}

/* ==========================================================
*                 [ Main functions ]
* =========================================================== */

public ev_TeamInfo( )
{
    static iId,szTeam[ 2 ];
    
    iId = read_data( 1 );
    read_data( 2,szTeam,charsmax( szTeam ) );
        
    if( GetPlayerBit( g_iAdmin,iId ) )
    {
        copy( g_szPlayerModel[ iId ],charsmax( g_szPlayerModel[ ] ),g_szModel[ GetPlayerBit( g_iGirl,iId ) ? ( szTeam[ 0 ] == 'T' ? 2:3 ):( szTeam[ 0 ] == 'T' ? 0:1 ) ] );
        set_user_info( iId,g_szCache_KeyModel,g_szPlayerModel[ iId ] );
    }
}

public fw_ClientKeyValue( iId,szBuffer[ ],szKey[ ],szValue[ ] )
{
    if( GetPlayerBit( g_iAdmin,iId ) && equal( szKey,g_szCache_KeyModel ) && !equal( szValue,g_szPlayerModel[ iId ] ) )
    {
        set_user_info( iId,szKey,g_szPlayerModel[ iId ] );
        
        return FMRES_SUPERCEDE;
    }
    
    return FMRES_IGNORED;
}

public message_ClCorpse( )
{
    static iId; iId = get_msg_arg_int( ARG_PLAYERID );
    
    if( GetPlayerBit( g_iAdmin,iId ) )
        set_msg_arg_string( ARG_MODELNAME,g_szPlayerModel[ iId ] );
}

/* ==========================================================
*                 [ Client-related ]
* =========================================================== */

public client_putinserver( iId )
{
    static iFlags; iFlags = get_user_flags( iId );
    
    if( iFlags & ADMIN_KICK )
    {
        SetPlayerBit( g_iAdmin,iId );

        if( iFlags & ADMIN_LEVEL_H )
            SetPlayerBit( g_iGirl,iId );
    }
}

public client_disconnect( iId ) ClearPlayerBit( g_iAdmin,iId ); 


[kikizon2]

Código PHP:

public plugin_precache( )
{
    new szData[ 64 ];
    
    for( new i;i < sizeof( g_szModel );i++ )
    {
        formatex( szData,charsmax( szData ),"models/player/%s/%s.mdl",g_szModel[ i ],g_szModel[ i ] );
        precache_model( szData );

        formatex( szData,charsmax( szData ),"models/player/%s/%sT.mdl",g_szModel[ i ],g_szModel[ i ] );
        if(file_exists(szData)) precache_model( szData );
    }
} 


[Rider430]

Me volviste a salvar la vida kikizon , Solucionado

[La Renga Mk]

hola ya que estamos en el tema

estoy haciendo algo parecido me pueden decir si esta bien echo ?

Código PHP:

new const g_admin_model_ct[] = "admin_ct_1"

new const g_admin_model_normal[] = "admin_normal_1"

new const g_admin_model_tt[][] = {
    "admin_tt_1",
    "admin_tt_2",
    "admin_tt_3"
} 


Código PHP:

public plugin_precache()
{
    precache_player_model(g_admin_model_ct)
    precache_player_model(g_admin_model_normal)
    
    static i;
    for(i = 0; i < sizeof(g_admin_model_tt); ++i) precache_player_model(g_admin_model_tt[i]);

} 


Código PHP:

stock precache_player_model(const modelname[]) 
{ 
    static longname[128]
    formatex(longname, charsmax(longname), "models/player/%s/%s.mdl", modelname, modelname) 
    precache_model(longname) 
    
    copy(longname[strlen(longname)-4], charsmax(longname) - (strlen(longname)-4), "T.mdl") 
    if (file_exists(longname)) precache_model(longname) 
} 


Codigo completo

Código PHP:

#include <amxmodx>
#include <amxmisc>
#include <cstrike>
#include <hamsandwich>
#include <cs_player_models_api>

new const g_admin_model_ct[] = "admin_ct_1"

new const g_admin_model_normal[] = "admin_normal_1"

new const g_admin_model_tt[][] = {
    "admin_tt_1",
    "admin_tt_2",
    "admin_tt_3"
}

public plugin_precache()
{
    precache_player_model(g_admin_model_ct)
    precache_player_model(g_admin_model_normal)
    
    static i;
    for(i = 0; i < sizeof(g_admin_model_tt); ++i) precache_player_model(g_admin_model_tt[i]);

}
public plugin_init() 
{
    register_plugin("Simple Admin Models", "1.0", "JoNaThAnxD")
    RegisterHam(Ham_Spawn, "player", "Admin_Models_Spawn", 1)
    RegisterHam(Ham_Killed, "player", "Admin_Models_Spawn", 1)  
}
public Admin_Models_Spawn(id) 
{
    if (!is_user_alive(id) || !cs_get_user_team(id))
        return PLUGIN_HANDLED;
    
    cs_set_player_model(id, g_admin_model_normal)
 
    if (is_user_admin(id)) 
    {
        new CsTeams:team = cs_get_user_team(id)
    
        if (team == CS_TEAM_CT) cs_set_player_model(id, g_admin_model_ct)
        else if(team == CS_TEAM_T) cs_set_player_model(id, g_admin_model_tt[random(sizeof(g_admin_model_tt))])
        else cs_reset_player_model(id)
    }
    return PLUGIN_CONTINUE
}
stock precache_player_model(const modelname[]) 
{ 
    static longname[128]
    formatex(longname, charsmax(longname), "models/player/%s/%s.mdl", modelname, modelname) 
    precache_model(longname) 
    
    copy(longname[strlen(longname)-4], charsmax(longname) - (strlen(longname)-4), "T.mdl") 
    if (file_exists(longname)) precache_model(longname) 
} 


[kikizon2]

No entiendo lo que quieres lograr en tu código...