[ZA] Como agregar extra items a un ZA 4.6

[TrikyTrakes]

Lo que yo quiero saber es como se agregan extra items a un zombie apocalypse 4.6 soy nueevo en los plugins y un amigo me invito a esta par gracias de adelantado

[kikizon2]

A esta par.?

Es facil para agregar extra items solo necesitas ver el zombieapocalypse.ini para ver que es lo que le necesitas cambiar, ahi algunas natives que pasan de zp_ a za_ postea el extra item que quieres adaptar y te ayudo o mandamelo por fb

[RauliTop]

ini no, el inc

[kikizon2]

.inc lo siento ando safado xD

[TrikyTrakes]

Va yo te lo paso xd y no kise decir par kise decir pag xd

[Pipa Roja]

Tutorial para adaptar clases e items extra

Código PHP:

/*======================================================
------------- [ Zombie Apocalypse 4.6 ] ----------------
========================================================

---- TUTORIAL: Crear Clase de Zombie Simple para ZA -----------*/

#include <amxmodx>
#include <zombieapocalypse> // registrar un el include zombieapocalypse ubicado en: addons/amxmodx/scripting/includes/

new const NameClass[] = "Zombie Tutorial" // Zombie Name
new const InfoClass[] = "This zombie is very funny!"  // Zombie Description
new const PlayerMDLClass[] = "zombie_source" // model player del zombie
new const ClawMDLClass[] = "v_knife_zombie.mdl" // model de las manos del zombie (Viewmodel)
const LevelClass = 5 // Level de la clase
const HPClass = 1600 // Vida del zombie
const SpeedClass = 230 // Velocidad del zombie
const Float:GravityClass = 0.7 // Gravedad del Zombie
const Float:KnockbackClass = 1.5 // Antiresistencia al poder de balas del zombie

new gNewClass // Crear una variable para detectar  mas tarde

// Start plugin_precache
public plugin_precache()
{
    register_plugin("[ZA] New ZClass", "1.0", "ChileScripting") // Register plugin
    
    /* Register Zombie Class */
    gNewClass = za_register_zombie_class(NameClass, InfoClass,  PlayerMDLClass, ClawMDLClass, LevelClass, HPClass, SpeedClass,  GravityClass, KnockbackClass)
}

// Llamar a una forward instalada en el zombie apocalypse, detectando cuando alguien se convirtio en zombie.
public zp_user_infected_post(id, nemali)
{
    if(nemali) // Chequiamos para ver si continuamos u.u
        return PLUGIN_HANDLED // si se cumple no continua
    
    if(zp_get_user_zombie_class(id) == gNewClass) // si la clase de zombie es la misma que esta clase
    {
        client_print(id, print_chat, "[ZA] Eres una clase nueva :D") // Print al user (:
    }
    
    return PLUGIN_CONTINUE;
}
/* Esto podria servirles para ahorrar bastante code
CheckValidZombie(id)
{
    if(za_get_user_alien(id) || zp_get_user_nemesis(id)) // si no es un zombie
        return false // negativo
        
    return true // si es zombie, verdadero
}*/ 


Código PHP:

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <engine>
#include <zombieapocalypse>

#define PLUGIN "New Plug-In"
#define VERSION 
#define AUTHOR 

new const NameItem[] = "Super Kit"
const LevelItem = 7
const CostItem = 15
const TeamItem = ZP_TEAM_HUMAN

new gNewItem

#define HPAMMOUNT 300.0
#define ARMORAMMOUNT 500.0

public plugin_init() {
    register_plugin("[ZA] New Extra-Item", "1.0", "ChileScripting")
    
    // Add your code here...
    gNewItem = za_register_extra_item(NameItem, LevelItem, CostItem, TeamItem)
}

public zp_extra_item_selected(id, ITEM)
{
    if(ITEM == gNewItem) // si el item seleccionado es el item gNewItem
    {
        static PlayerName[35] // crear variable 35 celdas
        get_user_name(id, PlayerName, charsmax(PlayerName)) // obtener nombre de id
        
        entity_set_float(id, EV_FL_health, entity_get_float(id, EV_FL_health) + HPAMMOUNT) // damos health points a id
        entity_set_float(id, EV_FL_armorvalue, entity_get_float(id, EV_FL_armorvalue) + ARMORAMMOUNT) // armor 
        
        client_print(0, print_chat, "[ZA] %s ha comprado %s", PlayerName, NameItem) // print
        client_cmd(id, "spk items/smallmedkit1.wav") // play the sound (default sound half life)
    }
} 


Código PHP:

/*======================================================
------------- [ Zombie Apocalypse 4.6 ] ----------------
========================================================

---- TUTORIAL: Crear Clase de Zombie Simple para ZA -----------*/

#include <amxmodx>
#include <zombieapocalypse> // registrar un el include zombieapocalypse ubicado en: addons/amxmodx/scripting/includes/

new const NameClass[] = "Humano Apocalypse" // Humano Name
new const InfoClass[] = "This human is warrior"  // Humano Description
new const PlayerMDLClass[] = "sas" // model player del Humano
const LevelClass = 10 // Level de la clase
const HPClass = 190 // Vida del Humano
const SpeedClass = 260 // Velocidad del Humano
const Float:GravityClass = 0.9 // Gravedad del Humano

new gHMNewClass // Crear una variable para detectar  mas tarde

// Start plugin_precache
public plugin_precache()
{
    register_plugin("[ZA] New ZClass", "1.0", "ChileScripting") // Register plugin
    
    /* Register Zombie Class */
    gHMNewClass = za_register_human_class(NameClass, InfoClass, PlayerMDLClass, LevelClass, HPClass, SpeedClass, GravityClass)
}

// Llamar a una forward instalada en el zombie apocalypse, detectando cuando alguien se convirtio en zombie.
public zp_user_humanized_post(id, survwesk)
{
    if(survwesk) // Chequiamos para ver si continuamos u.u
        return PLUGIN_HANDLED // si se cumple no continua
    
    if(za_get_user_human_class(id) == gHMNewClass) // si la clase de zombie es la misma que esta clase
    {
        client_print(id, print_chat, "[ZA] Eres una clase nueva humana :D.") // Print al user (:
        /* Aca abajo ejecutamos el code que queramos */
    }
    
    return PLUGIN_CONTINUE;
}
/* Podria servirles para ahorrar code
CheckValidHuman(id)
{
    if(za_get_user_wesker(id) || zp_get_user_survivor(id)) // si no es un humano
        return false // negativo
        
    return true // si es humano, verdadero
}*/