admin chat color simple

[subsero1]

bueno pille varios admin chat pero creo que son muy complicados editar . queria pedir porfa si me ayudan con algo mas sensillo para mis admin

2 tag 1 de hombre otro de mujer

[Admin]Nombre : Hola!
[Admina]Nombre : Hola!


color de mensaje ejemplo

green [aqua Admin green] aqua Nombre : green Hola!
green [ pink Admina green ] pink Nombre green : pink Hola!


las mujeres con la letra T escriben rosado


color de las [ ] green
color de mujer pink Admina - nombre de la admina - mensaje de la admina
color de los : green
color de aqua Admin - nombre de admin - mensaje de admin

[[R]ak]

really? admina? #todEs #lEs #diputadEs

no se puede color rosa ni color aqua(supongo que sera celeste)

Código PHP:

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "New Plug-In"
#define VERSION "1.0"
#define AUTHOR "[R]ak"

new g_MsgSayText, g_MaxPlayers, g_AdminTag[33][10]

enum _:Data {
    TAG[10],
    FLAG
}

new const AdminsTags[][Data] = {
    { "[ADMIN]", ADMIN_LEVEL_G },
    { "[ADMINA]", ADMIN_LEVEL_H }
}

const SPECT = 3

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_clcmd("say", "cmdSay")
    
    g_MaxPlayers = get_maxplayers()
    
    g_MsgSayText = get_user_msgid("SayText")
}

public client_putinserver(id) {
    
    if(!is_user_admin(id)) {
        copy(g_AdminTag[id], charsmax(g_AdminTag[]), "")
        return
    }
        
    new Flags = get_user_flags(id)
    
    for(new i; i < sizeof AdminsTags; i++) {
        if(Flags & AdminsTags[i][FLAG]) {
            copy(g_AdminTag[id], charsmax(g_AdminTag[]), AdminsTags[i][TAG])
            break;
        }
    }
    
}

public cmdSay(id)
{
    static Text[192]
    read_args(Text, charsmax(Text))
    remove_quotes(Text)
    
    replace_all(Text, charsmax(Text), "%", "")
    
    replace_all(Text, charsmax(Text), "#", "")
    
    if(!ValidMessage(Text))
        return PLUGIN_HANDLED
    
    static Name[32], Alive, Message[192]
    get_user_name(id, Name, charsmax(Name))
    
    Alive = is_user_alive(id)
    
    formatex(Message, charsmax(Message), "^x04%s %s^x03%s^x01 : %s", g_AdminTag[id], get_user_team(id) == SPECT ? "^x01*SPEC* " : !Alive ? "^x01*DEAD* " : "", Name, Text)
    
    for( new i = 1; i <= g_MaxPlayers; i++ ) {
        if(!is_user_connected(i) || is_user_alive(i) != Alive)
            continue;
        
        message_begin(MSG_ONE_UNRELIABLE, g_MsgSayText, _, i)
        write_byte(id)
        write_string(Message)
        message_end()
    }
    
    return PLUGIN_HANDLED_MAIN;
}

ValidMessage(text[]) {
    static len, i
    len = strlen(text)
    
    if(!len)
        return false
    
    for(i = 0; i < len; i++) {
        if( text[i] != ' ' ) {
            return true
        }
    }

    return false
} 


salen los 2 de color verde los prefijos

; s - custom level G
; t - custom level H

si tiene la T sale ADMINA

[subsero1]

vale compa lo probare , gracias por tu tiempo , lo pruebo y te aviso

[subsero1]

alguna posibilidad de cambiar el color de las letras a rosado ? seria ideal que las mujeres escribieran rosado

[Skylar]

alguna posibilidad de cambiar el color de las letras a rosado ? seria ideal que las mujeres escribieran rosado

No se puede en rosado y no vas a conseguir novia haciendo eso

[subsero1]

que color mas aparte del verde , azul y rojo , blanco se puede usar ?

[totopizza]

que color mas aparte del verde , azul y rojo , blanco se puede usar ?

No se puede, esos colores dependen segun el valor que asignas en con_color de tu cs