como crear menu on/off

[alonso_9]

Buenas, necesito saver como crear un menu donde yo pueda opcionalmente activar y desactivar algo , algo parecido al menu del bhop que se puede activar y desactivar en alguno servidores , quiero aprender a hacerlo para aplicarlo en otras cosas como desactivar funciones de alguno plugins

[CSAxel]

Código PHP:

// Ejemplo de un menú
public menuTest(const id)
{
    new iMenuId;
    new sMenu[32];

    iMenuId = menu_create("TEST", "menuHandlerTest");

    formatex(sMenu, 31, "Activar funciónTest \y(%s)", (g_FuncionTest[id]) ? "Si" : "No");
    menu_additem(iMenuId, sMenu, "1");

    menu_setprop(iMenuId, MPROP_EXITNAME, "Salir");
    menu_display(id, iMenuId);
}

public menuHandlerTest(const id, const menu, const item)
{
    if(!is_user_connected(id) || item == MENU_EXIT)
    {
        menu_destroy(menu);
        return PLUGIN_HANDLED;
    }

    new iItemId;
    new sItem[2];
    new iDummy;

    menu_item_getinfo(menu, item, iDummy, sItem, 1, _, _, iDummy);
    menu_destroy(menu);

    iItemId = str_to_num(sItem);

    switch(iItemId)
    {
        case 1: g_FuncionTest[id] = !g_FuncionTest[id];
    }

    return PLUGIN_HANDLED;
}

// Ejemplo de función a la que queres activar o desactivar
public funcionTest(const id)
{
    if(!g_FuncionTest[id])
        return;

    // Lo que quieras que haga dicha función
} 


Para la activación o desactivación de una función es recomendable usar una variable para eso (g_FuncionTest por ejemplo) para que desde el menú este en 0 o 1 para que determine si activará o no dicha función