[ZP] increase_zombie_crouchspeed

[mielatenas]

Hola soy nuevo aqui y antes que un request me gustaria que me informaran de un plugin que ya lo haga, sucede que en mi zp_zombieclasses archivos todas las clases son lentas porque me gusta el efecto de que se acerquen lentamente, la más baja de todas es "185" (el zomb gordo) los demás no sobrepasana los 220 max. sucede que si la velocidad de un jugador es menor a "220" (240 es la velocidad default cs) si estás agachado en un sitio como los ductos, tu aceleración no da para que termines de pasar por el ducto por los disparos (y eso que no tienen knockback activo) o cuando giros bruscos de dirección.

   

Sería un plugin que incrementaría velocidad de zombs mientras agachado, podría ser solo si la velocidad es menor que este valor "220" el cuál probé es el minimo de velocidad antes de que pase.
y por su puesto si es menor a "185" te quedas sin velocidad absolutamente

Fue dificil encontrarlo es algunos plugins la acción +IN_DUCK pero nosé como debería de ser usada para que se aplique a todos los zombies independientepente de su clase

[samueldmq]

No idea de algún plugin que haga eso, pero pruébate este a ver si te sirve, es pa zp_50 xd

Código PHP:

#include <amxmodx>
#include <fakemeta>
#include <zp50_core>
#include <zp50_gamemodes>
#include <fun>

#define PLUGIN "ZP No se que nombre poner"
#define VERSION "1.0"
#define AUTHOR "Samueldmq"

#define MAX_SPEED 225.0

#define SetBitUserZombie(%1)      (g_bitsIsUserZombie |= (1<<(%1&31)))
#define ClearBitUserZombie(%1)    (g_bitsIsUserZombie &= ~(1 <<(%1&31)))
#define CheckBitUserZombie(%1)    (g_bitsIsUserZombie & (1<<(%1&31)))

new g_bitsIsUserZombie
new Float:g_fUserMaxSpeed[32]
new g_iMaxPlayers


public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_forward(FM_CmdStart,"fwd_CmdStart")
    
    g_iMaxPlayers = get_maxplayers()
}

public zp_fw_gamemodes_start(game_mode_id) {
    for(new i = 1; i < g_iMaxPlayers; i++) {
        if(!is_user_alive(i)) 
            continue
        
        if(zp_core_is_zombie(i)) {
            SetBitUserZombie(i)
            g_fUserMaxSpeed[i-1] = get_user_maxspeed(i)
        } else {
            ClearBitUserZombie(i)
        }
    }
}

public zp_fw_core_infect_post(id, attacker) {
    g_fUserMaxSpeed[id-1] = get_user_maxspeed(id)
    SetBitUserZombie(id)
}

public zp_fw_core_cure_pre(id, attacker) {
    ClearBitUserZombie(id)
}

public zp_fw_core_spawn_post(id) {
    g_fUserMaxSpeed[id-1] = get_user_maxspeed(id)
}

public fwd_CmdStart(id, uc_handle, seed) {
    if(!is_user_alive(id) || !CheckBitUserZombie(id)) return FMRES_IGNORED
    
    static buttons, oldbuttons
    
    buttons = get_uc(uc_handle, UC_Buttons)
    oldbuttons = pev(id, pev_oldbuttons)
    
    if(buttons&IN_DUCK && !(oldbuttons&IN_DUCK)) {
        if(get_user_maxspeed(id) < 220.0) {
            set_user_maxspeed(id, MAX_SPEED)
        }
        
        return FMRES_HANDLED
    } 
    else if(!(buttons&IN_DUCK) && oldbuttons&IN_DUCK) {
        if(CheckBitUserZombie(id)) {
            set_user_maxspeed(id, g_fUserMaxSpeed[id-1])
            
            return FMRES_HANDLED
        }
    }
    
    return FMRES_IGNORED
} 


Espero te sirva