Guardar frag y muerte solo por mapa

[Spirit]

Hola todos, como estas?... Estuve buscando un tema con respecto a guardar frag y la muerte solo por mapa, que al desconectarse se guarde esos datos, pero solo en ese mismo mapa.Es posible usando Tries, pero no lo encuentro, si alguien me pasa ese codigo o el tema por favor, se lo agradecería muchísimo, gracias

[Mía]

Código PHP:

#include <amxmodx>
#include <cstrike>
#include <fun>

#define PLUGIN "Save Frags & Deaths"
#define VERSION "0.1"

new Trie:g_tFrags, Trie:g_tDeaths;
new g_Disconnected[33];

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, "Mia2904");
    
    g_tFrags = TrieCreate();
    g_tDeaths = TrieCreate();
    
    register_message(get_user_msgid("ScoreInfo"), "message_ScoreInfo");
}

public client_putinserver(iId)
{
    new szAuth[35];
    get_user_authid(iId, szAuth, charsmax(szAuth));
    
    // szAuth desde posicion 6 para no guardar la parte STEAM_
    if (TrieKeyExists(g_tFrags, szAuth[6]))
    {
        new iFrags, iDeaths;
        TrieGetCell(g_tFrags, szAuth[6], iFrags);
        TrieGetCell(g_tDeaths, szAuth[6], iDeaths);
        
        set_user_frags(iId, iFrags);
        cs_set_user_deaths(iId, iDeaths);
    }
    
    g_Disconnected[iId] = 0;
}

public client_disconnected(id)
{
    g_Disconnected[id] = 1;
}

public message_ScoreInfo(iMsgId, iMsgDest, iMsgEnt)
{
    new iId, iFrags, iDeaths;
    iId = get_msg_arg_int(1);
    
    if(g_Disconnected[iId])
        return;
    
    iFrags = get_msg_arg_int(2);
    iDeaths = get_msg_arg_int(3);
    
    new szAuth[35];
    get_user_authid(iId, szAuth, charsmax(szAuth));
    
    TrieSetCell(g_tFrags, szAuth[6], iFrags);
    TrieSetCell(g_tDeaths, szAuth[6], iDeaths);
} 


Créditos a @r0ma'

[Spirit]

Muchas gracias, lo voy a probar

---

Una consultita, viendo los tutoriales, hace falta distruirlo al termina el mapa?

[Mía]

Muchas gracias,  lo voy a probar

---

Una consultita, viendo los tutoriales, hace falta distruirlo al termina el mapa?

En versiones muy antiguas de AMXX sí era necesario, ya no lo es desde hace mucho.

[Spirit]

Bueno Mia, y en el caso que en ves de steamId, que sea por name, tendria que reemplazar szAuth?,

Código PHP:

get_user_authid(iId, szAuth, charsmax(szAuth)); 


por

Código PHP:

get_user_name(iId, szAuth, charsmax(szAuth)); 


y en la consulta quedaria:

Código PHP:

if (TrieKeyExists(g_tFrags, szAuth)) 


verdad?

Me gustaria que fuese por name por favor

[Hinami]

https://amxmodx-es.com/showthread.php?tid=32

si pero fijate que hay 2 get_user_authid