menu de Knife por niveles

[Soy nuevo]

Alguien me pasa algun menu de knife(facas/cuchillos) restringido por niveles?

Gracias.

[Hinami]

Código PHP:

#include <amxmodx>
#include <hamsandwich>
#include <fakemeta>

new const P_INFO[][] = { "KnifeMenu", "1.0", "kikizon" };

new kKnifeSelected[ 33 ];

enum _:KNIFE_DATA { KNIFE_NAME[30], KNIFE_VMDL[ 50 ], KNIFE_PMDL[ 50 ], LVL }

new const Knifes[][KNIFE_DATA] =
{
    /* Para agregar Knifes */
    
    // Nombre    //        V_ MDL        //        P_MDL        //
    { "Default",     "models/v_knife.mdl",     "models/p_knife.mdl", 1 },
    { "Karambit",     "models/bk/v_karambit.mdl", "models/bk/p_karambit.mdl", 2 }
};

public plugin_precache()
{
    for(new k = 1; k < sizeof Knifes; ++k)
    {
        precache_model( Knifes[ k ][ KNIFE_VMDL ]);
        precache_model( Knifes[ k ][ KNIFE_PMDL ]);
    }
}

public plugin_init() 
{
    register_plugin( P_INFO[ 0 ], P_INFO[ 1 ], P_INFO[ 2 ] );
    
    RegisterHam(Ham_Item_Deploy, "weapon_knife", "ham_KnifeDeployPost", true );
    
    register_clcmd( "say /knife", "ShowMenuKnifes" );
}

public ham_KnifeDeployPost( wpn_ent )
{
    static kOwner; kOwner = get_weapon_ent_owner( wpn_ent );
    
    if ( !pev_valid(kOwner) || !is_user_alive( kOwner ) ) return;
    
    set_pev( kOwner, pev_viewmodel2, Knifes[ kKnifeSelected[kOwner] ][ KNIFE_VMDL ] );
    set_pev( kOwner, pev_weaponmodel2, Knifes[ kKnifeSelected[kOwner] ][ KNIFE_PMDL ] );
}

public ShowMenuKnifes( index )
{
    static k, knife[40], menu; 
    menu = menu_create("\wMenu de Knifes", "menu_knifes" );
    
    for(k = 0; k < sizeof Knifes; ++k )
    {
        if( kKnifeSelected[ index ] == k )
        {
            formatex( knife, charsmax(knife), "\d%s \r[ \yACTUAL \r]", Knifes[ k ][ KNIFE_NAME ] );
            menu_additem( menu, knife, "" );
        }
        else 
        {
            if( g_level[ index ] >= Knifes[ k ][ LVL ] )
                menu_additem( menu, Knifes[ k ][ KNIFE_NAME ], "" );
            else {
                formatex( knife, charsmax(knife), "\d%s \r[ \nivel: %d \r]", Knifes[ k ][ KNIFE_NAME ], Knifes[ k ][ LVL ] );
                menu_additem( menu, knife, "" );
             }
        }
    }
    
    menu_display( index, menu );
}

public menu_knifes( index, menu, item )
{
    if( item == MENU_EXIT )
    {
        menu_destroy( menu );
        return PLUGIN_HANDLED;
    }
    
    if( kKnifeSelected[ index ] == item )
    {
        client_print( index, print_center, "Ya elegiste este knife");
        return PLUGIN_HANDLED;
    }

    if( g_level[ index ] < Knifes[ item ][ LVL ])
    {
        client_print( index, print_chat, "Necesitas ser nivel: %d", Knifes[ item ][ LVL ] );
        return PLUGIN_HANDLED;
    }
    
    kKnifeSelected[ index ] = item;
    engclient_cmd( index, "weapon_knife");
    
    menu_destroy( menu );
    return PLUGIN_HANDLED;
}

stock get_weapon_ent_owner(ent)
{
    if (pev_valid(ent) != 2)
        return -1;
    
    return get_pdata_cbase(ent, 41, 4);
} 


[Soy nuevo]

Y el nivel iría acá no?

Código PHP:

{ "Karambit",     "models/bk/v_karambit.mdl", "models/bk/p_karambit.mdl", 2 } 


El 2 seria el niveles cierto?

o donde iría?

[Hinami]

si

enum _:KNIFE_DATA { KNIFE_NAME[30], KNIFE_VMDL[ 50 ], KNIFE_PMDL[ 50 ], LVL }
ahí dice

[Soy nuevo]

Ahora lo pruebo y te digo

Pero igual tengo una duda ese 2 .. no sera el numero que tiene que apretar para que seleccione la faca?

osea el 2 seria el case 1
y el 1 case 0

[Hinami]

ño el 2 es el nivel :b